# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="Various sparc utilites from Debian GNU/Linux"
HOMEPAGE="http://www.debian.org/"
SRC_URI=" http://http.us.debian.org/debian/pool/main/s/${PN}/${PN}_${PV}.orig.tar.gz
	mirror://gentoo/${PN}_${PV}-2.diff.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="sparc -x86 -ppc"
IUSE=""

DEPEND="sys-kernel/linux-headers"
RDEPEND="virtual/glibc
	sys-devel/sparc32"

S="${WORKDIR}/${P}.orig"

src_unpack() {
	unpack ${A}
	epatch ${WORKDIR}/${PN}_${PV}-2.diff
}

src_compile() {
	local CFLAGS="-O3"

	emake -C elftoaout-2.3 CFLAGS="${CFLAGS}" || die
	emake -C src piggyback piggyback64 CFLAGS="${CFLAGS}" || die
	emake -C prtconf-1.3 all || die
	emake -C audioctl-1.3 || die

	# sparc32 is in sys-devel/sparc32
	# emake -C sparc32-1.1
}

src_install() {
	dobin elftoaout-2.3/elftoaout || die
	dobin src/piggyback || die
	dobin src/piggyback64 || die
	dosbin prtconf-1.3/prtconf || die
	dosbin prtconf-1.3/eeprom || die
	
	dobin audioctl-1.3/audioctl || die

	exeinto /etc/init.d; newexe ${FILESDIR}/audioctl.init audioctl || die
	insinto /etc/conf.d; newins debian/audioctl.def audioctl || die

	doman audioctl-1.3/audioctl.1
	doman elftoaout-2.3/elftoaout.1
	doman prtconf-1.3/prtconf.8
	doman prtconf-1.3/eeprom.8
	doman debian/piggyback.1
	doman debian/piggyback64.1
}

pkg_postinst() {
	einfo "Adding /dev/openprom device"
	if [ -e /dev/openprom ] ; then
		rm -f /dev/openprom
	fi
	mknod /dev/openprom c 10 139 || die
}