app-dicts/goldendict universal 0.8.0 and live

goldendict-0.8.0.ebuild (text/plain), 2.38 KB, created by Sergey Kondakov on 2009-04-26 14:04:26 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="svn://svn.berlios.de/goldendict/trunk/src"
	ESVN_PROJECT="goldendict"
	inherit subversion
	SRC_URI=""
	KEYWORDS=""
else
	inherit eutils
	SRC_URI="mirror://berlios/${PN}/${P}-src-x11.tar.bz2 -> ${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86 ~x86-fbsd"
	S="${WORKDIR}/${P}-src"
fi

RUPACK="enruen-content"
RUPACK_V="1.0"

inherit qt4
DESCRIPTION="GoldenDict is a feature-rich dictionary lookup program."
HOMEPAGE="http://goldendict.berlios.de/"
LICENSE="GPL-3"
SLOT="0"

LANGS="af bg ca cs cy da de de-alt el en eo es et fo fr ga gl he hr hu ia id it ku lt lv mi mk ms nb nl nn pl pt ro ru sk sl sv sw tn uk zu"
IUSE=""
for i in ${LANGS}; do
	IUSE="${IUSE} linguas_${i}"
done

# let's have some en<->ru dictionaries and english-pronouncing pack
SRC_URI="${SRC_URI}
	linguas_ru? ( mirror://berlios//${PN}/${RUPACK}-${RUPACK_V}.tar.bz2 )"

RDEPEND="sys-libs/zlib
	>=dev-libs/libzip-0.9
	app-text/hunspell
	media-libs/libogg
	media-libs/libvorbis
	>=x11-libs/qt-core-4.5
	>=x11-libs/qt-webkit-4.5"
DEPEND="${RDEPEND}"
for i in ${LANGS}; do
	RDEPEND="${RDEPEND}
		linguas_${i}? ( app-dicts/myspell-${i} )"
done

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		subversion_src_unpack
	else
		unpack "${P}.tar.bz2"
	fi

	if use linguas_ru; then
		mkdir "${WORKDIR}"/rupack
		cd "${WORKDIR}"/rupack
		unpack "${RUPACK}-${RUPACK_V}.tar.bz2"
	fi
}

src_prepare() {
	# hunspell naming fix. version-independent
	sed -i -e "s:-lhunspell:$(pkg-config --libs-only-l hunspell):" goldendict.pro
}

src_compile() {
	eqmake4 || die "qmake failed"
	emake || die "emake failed"
}

src_install() {
	# not used. yet
	# emake INSTALL_ROOT="${D}" install || die "emake install filed"

	dobin goldendict || die "failed to install executable"
	insinto "/usr/share/${PN}"
	doins -r flags icons || die "failed to put datafiles in place"
	newicon icons/programicon.png ${PN}.png
	make_desktop_entry ${PN} GoldenDict ${PN}.png "Qt;Utility;Dictionary;"

	if use linguas_ru; then
		insinto "/usr/share/apps/${PN}"
		doins -r "${WORKDIR}"/rupack/content/* || die
	fi
}

pkg_postinst() {
	elog "add '/usr/share/myspell' to your \"Morphology\" source"

	if use linguas_ru; then
		elog
		elog "add '/usr/share/apps/goldendict' to your"
		elog "\"Dictionaries\", \"Morphology\" and \"Sound\" sources"
	fi
}