# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

RUPACK="enruen-content"
RUPACK_V="1.0"

inherit eutils qt4
DESCRIPTION="GoldenDict is a feature-rich dictionary lookup program."
HOMEPAGE="http://goldendict.berlios.de/"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"

LANGS="af bg ca cs cy da de de-alt el en eo es et fo fr ga gl he hr hu ia id it ku lt lv mi mk ms nb nl nn pl pt ro ru sk sl sv sw tn uk zu"
IUSE=""
for i in ${LANGS}; do
	IUSE="${IUSE} linguas_${i}"
done

SRC_URI="mirror://berlios/${PN}/${P}-src-x11.tar.bz2
	 linguas_ru? ( mirror://berlios//${PN}/${RUPACK}-${RUPACK_V}.tar.bz2 )"

RDEPEND="sys-libs/zlib
	>=dev-libs/libzip-0.9
	app-text/hunspell
	media-libs/libogg
	media-libs/libvorbis
	>=x11-libs/qt-core-4.5
	>=x11-libs/qt-webkit-4.5"
DEPEND="${RDEPEND}"
for i in ${LANGS}; do
	RDEPEND="${RDEPEND}
		linguas_${i}? ( app-dicts/myspell-${i} )"
done

PROVIDE="virtual/stardict"
S="${WORKDIR}/${P}-src"

src_unpack() {
	unpack "${P}-src-x11.tar.bz2"
	cd "${S}"

	sed -i -e "s:-lhunspell:$(pkg-config --libs-only-l hunspell):" goldendict.pro

	if use linguas_ru; then
		mkdir ${WORKDIR}/rupack
		cd ${WORKDIR}/rupack
		unpack "${RUPACK}-${RUPACK_V}.tar.bz2"
	fi
}

src_compile() {
	QMAKE_FLAGS=""
	eqmake4 $QMAKE_FLAGS || die "qmake failed"
	emake || die "emake failed"
}

src_install() {
	# not used. yet
	# emake INSTALL_ROOT="${D}" install || die "emake install filed"

	dobin goldendict || die "failed to install executable"
	insinto "/usr/share/${PN}"
	doins -r flags icons || die "failed to put datafiles in place"
	newicon icons/programicon.png ${PN}.png
	make_desktop_entry ${PN} GoldenDict ${PN}.png "Qt;Utility;Dictionary;"

	if use linguas_ru; then
		insinto "/usr/share/apps/${PN}"
		doins -r ${WORKDIR}/rupack/content/* || die
	fi
}