# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit qt4 cmake-utils eutils

MY_P="${PN}-${PV/_beta/.beta}"
DESCRIPTION="Desktop Publishing (DTP) and Layout program for Linux"
HOMEPAGE="http://www.scribus.net"
SRC_URI="mirror://sourceforge/scribus/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="+cairo debug"

RDEPEND="x11-libs/qt-core
	x11-libs/qt-gui
	media-libs/freetype:2
	media-libs/lcms
	sys-libs/zlib
	media-libs/libpng
	media-libs/jpeg
	media-libs/tiff
	net-print/cups
	media-libs/fontconfig
	dev-libs/libxml2
	app-text/aspell
	dev-lang/python
	media-libs/podofo
	dev-libs/libxml2
	dev-libs/boost
	virtual/ghostscript
	cairo? ( >=x11-libs/cairo-1.4 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/cmake"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Fix lib2geom relocation errors on amd64
	if use amd64 ; then
		epatch "${FILESDIR}/${PN}-1.3.5-fpic.patch"
	fi
}

src_configure() {
	mycmakeargs="${mycmakeargs} -DWANT_NORPATH:BOOL=TRUE
		$(cmake-utils_use_want cairo CAIRO)
		$(cmake-utils_use_want debug DEBUG)"

	if use amd64 ; then
		mycmakeargs="${mycmakeargs} -DWANT_LIB64:BOOL=TRUE"
	fi

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	dodoc AUTHORS ChangeLog README TODO

	domenu scribus.desktop
	doicon scribus/icons/scribus.png
}