ebuild for 0.5-20080619

n2hell-bin-0.5.20080619.ebuild (text/plain), 1.61 KB, created by Michał Górny on 2009-04-13 09:49:55 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

DESCRIPTION="AJAX webUI for rtorrent written in Java"

MY_PV="${PV%.*}-${PV#*.*.}"
MY_P="${PN%-bin}-${MY_PV}"

HOMEPAGE="http://code.google.com/p/n2hell/"
SRC_URI="http://n2hell.googlecode.com/files/${MY_P}.zip"

LICENSE="|| ( AFL-2.1 BSD ) GPL-3" # first two for Dojo
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND=">=virtual/jre-1.5
	>=net-p2p/rtorrent-0.7.8[xmlrpc]"

S="${WORKDIR}/${MY_P}"

src_install() {
	DIR=/opt/n2hell
	DOCS='changelog.txt install.txt'

	dodoc ${DOCS}

	# cleanup a little
	rm n2hell.{sh,bat} ${DOCS}

	# we provide our own startscript
	exeinto /opt/bin
	doexe "${FILESDIR}"/n2hell

	insinto ${DIR}
	doins -r .

	newinitd "${FILESDIR}"/init.d n2hell
	newconfd "${FILESDIR}"/conf.d n2hell
}

pkg_postinst() {
	elog "To get n2hell working, you need to enable xmlrpc in your rtorrent.rc like so:"
	elog "  scgi_port = 127.0.0.1:5000"
	elog "As this may pose as security risk, if your machine is multi-user you may"
	elog "consider using xt_owner to limit access to trusted users. n2hell doesn't"
	elog "support safer 'scgi_local'."
	echo
	elog "You can run n2hell either manually (/opt/bin/n2hell) or using supplied init.d"
	elog "script. By default, it will be listening on:"
	elog "  http://127.0.0.1:8888/"
	elog "The default user/pass is admin:admin."
	echo
	elog "Please note that the configuration dialog tends to work only with Mozilla"
	elog "browser, so you'll probably need to use it for the first run of n2hell."
	elog "But afterwards any modern browser should work fine."
}