Work in progress ebuild

logjam-4.5.3.ebuild (text/plain), 1.20 KB, created by Mart Raudsepp on 2009-04-13 01:34:58 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/logjam/logjam-4.5.3.ebuild,v 1.2 2006/01/12 23:45:26 compnerd Exp $

EAPI=1

DESCRIPTION="GTK2-based LiveJournal client"
HOMEPAGE="http://logjam.danga.com/"
SRC_URI="http://logjam.danga.com/download/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk gtkhtml spell sqlite svg"

RDEPEND=">=dev-libs/libxml2-2
	net-misc/curl
	gtk? ( >=x11-libs/gtk+-2.4 )
	gtkhtml? ( gnome-extra/gtkhtml:3.6 )
	spell? ( app-text/gtkspell )
	sqlite? ( >=dev-db/sqlite-3 )
	svg? ( >=gnome-base/librsvg-2.2.3 )"

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.29
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	sed -i -e s/logjam.png/logjam_pencil.png/ "${S}"/data/logjam.desktop.in || die "sed failed"
}

src_compile() {
	econf \
	$(use_with gtk) \
	$(use_with gtkhtml gtkhtml36) \
	$(use_with spell gtkspell) \
	$(use_with svg librsvg) \
	$(use_with sqlite sqlite3) \
	--without-xmms || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc ChangeLog doc/README doc/TODO || die "dodoc failed"
}