# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils 

DESCRIPTION="Java based Least Cost Router for Germany"
HOMEPAGE="http://www.bongosoft.de"

MY_P="BongoSurfer-${PV}-src"
S="${WORKDIR}/${MY_P}"

SRC_URI="http://www.bongosoft.de/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND="
	>=dev-java/jdictrayapi-0.9.1-r2
	>=virtual/jre-1.5
	net-dialup/ppp
	net-misc/ntp
	"
DEPEND="${RDEPEND}"


BONGO_INST="/usr/share/${PN}"

src_unpack() {
	unpack ${A}
	cd "${S}/skripte/modem"
	epatch "${FILESDIR}/modem.patch" 

	cd "${S}/skripte/bin"
	epatch "${FILESDIR}/gentoo-jdictrayapi.patch" 
}

src_install() {
	domenu apps/${PN}.desktop

	insinto /etc/${PN}
	doins config/*

	dodoc doc/*
	docinto pppoe; dodoc doc/pppoe/*
	docinto skripte; dodoc doc/skripte/*
	docinto pppoe/mtu; dodoc doc/pppoe/mtu/*

	doicon icons/${PN}.png 

	insinto ${BONGO_INST}/jar
	doins jar/*.jar 

	insinto ${BONGO_INST}/lib
	doins lib/*.jar 

	doman man/*.1

	insinto /etc/ppp/peers/bongosurfer
	doins peers/*

	dobin skripte/bin/${PN}
	fowners root:dialout /usr/bin/${PN}
	fperms 750 /usr/bin/${PN}

	dosbin skripte/sbin/bongosetup

	for dir in capi i4l modem time; do
		exeinto ${BONGO_INST}/skripte/${dir}
		doexe skripte/${dir}/*.sh
	done
}

pkg_postinst() {
	echo
	elog "Bongosurfer is using pppd's setuid facility by default."
	elog "If you want to make use of sudo instead, call bongosetup as root."
	echo
	ewarn "Anyway, you have to if you want to set the clock after connection."
	echo
}