conserver-8.0.1.ebuild

conserver-8.0.1.ebuild (text/plain), 1.67 KB, created by Thomas Eckert on 2003-10-03 07:04:19 UTC

# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="Conserver - Serial Console Manager"
HOMEPAGE="http://www.conserver.com/"
SRC_URI="ftp://ftp.conserver.com/conserver/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86"

IUSE="pam ssl"
DEPEND="ssl? ( >=dev-libs/openssl-0.9.6g )
	pam? ( sys-libs/pam )"

src_compile() {
	econf \
		$(use_with ssl openssl) \
		$(use_with pam) \
		--with-logfile=/var/consoles/conserver.log \
		--with-pidfile=/var/run/conserver.pid \
		--with-cffile=conserver/conserver.cf \
		--with-pwdfile=conserver/conserver.passwd \
		--with-master=localhost \
		--with-port=7782 || die "./configure failed"

	emake || die "compile failed"
}

src_install () {
	einstall exampledir=${D}/usr/share/doc/${PF}/examples || die "problem with install"

	## create data directory
	dodir /var/consoles
	fowners daemon.daemon /var/consoles
	fperms 700 /var/consoles

	## add startup and sample config
	exeinto /etc/init.d
	newexe ${FILESDIR}/conserver.initd conserver
	insinto /etc/conf.d
	newins ${FILESDIR}/conserver.confd conserver

	dodir /etc/conserver
	fowners daemon.daemon /etc/conserver
	fperms 700 /etc/conserver
	insinto /etc/conserver
	newins ${S}/conserver.cf/conserver.cf conserver.cf.sample
	newins ${S}/conserver.cf/conserver.passwd conserver.passwd.sample

	## add docs
	dohtml conserver.html
	dodoc CHANGES FAQ INSTALL LICENSE README TODO
	dodoc conserver/Sun-serial conserver.cf/INSTALL
	dodoc contrib/maketestcerts
	newdoc conserver.cf/conserver.cf conserver.cf.sample
}

pkg_postinst() {
	einfo "Config-file formats _changed_ with version 8.0 !"
	if use ssl; then
		einfo "You will need to create certificates to use the ssl-feature."
	fi
}