There you go

ddd-3.3.12.ebuild (text/plain), 1.65 KB, created by Maciej Mrozowski on 2009-03-25 03:46:42 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils

DESCRIPTION="Graphical front-end for command-line debuggers"
HOMEPAGE="http://www.gnu.org/software/ddd"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3 LGPL-3 FDL-1.1"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
SLOT="0"
IUSE="gnuplot"

DEPEND="
	>=sys-devel/gcc-3
	sys-devel/gdb
	x11-libs/libXaw
	x11-libs/libXpm
	>=x11-libs/openmotif-2.3
"
RDEPEND="${DEPEND}
	x11-apps/xfontsel
	gnuplot? ( sci-visualization/gnuplot )
"

RESTRICT="test"

src_install() {
	# Remove app defaults
	rm -f "${S}"/ddd/Ddd
	# Install ddd distribution
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS COPYING* CREDITS INSTALL NEWS PROBLEMS README TIPS TODO \
		|| die "dodoc failed"
	# Just install html docs
	dohtml -r "${S}"/doc/html/* || die "dohtml failed"
	# Install application icon
	doicon "${S}"/icons/ddd.xpm || die "doicon failed"
}

pkg_postinst() {
	if ! use gnuplot; then
		echo
		elog "To enable data visualization in DDD, install sci-visualization/gnuplot,"
		elog "or re-emerge DDD with gnuplot USE flag (recommended)."
		elog "For flat file package.use layout:"
		elog "   echo '${CATEGORY}/${PN} gnuplot' >> /etc/portage/package.use && emerge -va gnuplot"
		elog "For directory package.use layout:"
		elog "   echo '${CATEGORY}/${PN} gnuplot' > /etc/portage/package.use/ddd && emerge -va gnuplot"
	fi
	echo
	elog "To be able to debug java, bash, perl or python scripts within DDD, install respectively:"
	elog "    virtual/jdk"
	elog "    app-shells/bashdb"
	elog "    dev-lang/perl"
	elog "    dev-python/pydb"
	echo
}