Modified ebuild

qt-creator-1.0.0.ebuild (text/plain), 2.81 KB, created by Livid on 2009-03-19 23:58:31 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/qt-creator-1.0.0.ebuild,v 1.4 2009/03/12 17:02:51 hwoarang Exp $

EAPI="2"

inherit qt4 multilib

MY_PN="${PN/-/}"
MY_P="${P}-src"

DESCRIPTION="Lightweight IDE for C++ development centering around Qt"
HOMEPAGE="http://labs.qtsoftware.com/page/Projects/Tools/QtCreator"
SRC_URI="http://download.qtsoftware.com/${MY_PN}/${MY_P}.zip"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug
      doc
	  +plugin_find
	  +plugin_texteditor
	  +plugin_cppeditor
	  plugin_designer
	  +plugin_bineditor
	  +plugin_bookmarks
	  +plugin_projectexplorer
	  +plugin_vcsbase
	  +plugin_perforce
	  +plugin_subversion
	  +plugin_git
	  +plugin_cpptools
	  +plugin_qt4projectmanager
	  +plugin_quickopen
	  +plugin_debugger
	  +plugin_help
	  +plugin_qtscripteditor
	  +plugin_cmakeprojectmanager
	  +plugin_fakevim"

PLUGINS="plugin_find
	  plugin_texteditor
	  plugin_cppeditor
	  plugin_designer
	  plugin_bineditor
	  plugin_bookmarks
	  plugin_projectexplorer
	  plugin_vcsbase
	  plugin_perforce
	  plugin_subversion
	  plugin_git
	  plugin_cpptools
	  plugin_qt4projectmanager
	  plugin_quickopen
	  plugin_debugger
	  plugin_help
	  plugin_qtscripteditor
	  plugin_cmakeprojectmanager
	  plugin_fakevim"


DEPEND=">=x11-libs/qt-assistant-4.5.0_rc1
	>=x11-libs/qt-core-4.5.0_rc1
	>=x11-libs/qt-dbus-4.5.0_rc1
	>=x11-libs/qt-gui-4.5.0_rc1
	>=x11-libs/qt-qt3support-4.5.0_rc1
	>=x11-libs/qt-script-4.5.0_rc1
	>=x11-libs/qt-sql-4.5.0_rc1
	>=x11-libs/qt-svg-4.5.0_rc1
	>=x11-libs/qt-test-4.5.0_rc1
	>=x11-libs/qt-webkit-4.5.0_rc1"

RDEPEND="${DEPEND}
	|| ( media-sound/phonon >=x11-libs/qt-phonon-4.5.0_rc1 )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}/docs_gen.patch"
	# bug #261448
	for target in src/qworkbench.pri src/qworkbenchlibrary.pri src/qworkbenchplugin.pri;do
		einfo "Fixing ${target}"
		sed -i "s/lib\/qtcreator/$(get_libdir)\/qtcreator/" \
			${target} || die "seding ${target} failed"
	done

	einfo "Adding designer plugin"
	sed -i '/plugin_fakevim/s:$: \\:' src/plugins/plugins.pro
	sed -i '/plugin_fakevim/a\            plugin_designer' src/plugins/plugins.pro

	einfo "Configuring plugins"
	for plugin in ${PLUGINS};do
		if ! use ${plugin}; then
			sed -i "/${plugin}/s:^:#:" src/plugins/plugins.pro
		fi
	done 
}

src_configure() {
	eqmake4 ${MY_PN}.pro
}

src_install() {
	emake INSTALL_ROOT="${D}/usr" install || die "emake install failed"
	if use doc;then
		insinto /usr/share/doc/qtcreator/
		doins "${S}"/share/doc/qtcreator/qtcreator.qch || die "Installing documentation failed"
		doins -r "${S}"/doc/html || die "Installing html documentation  failed"
	fi
	make_desktop_entry qtcreator QtCreator qtcreator_logo_48 \
		'Qt;Development;IDE' || die "make_desktop_entry failed"
}