# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="OpenMap is a graphical toolkit for showing and manipulating geospatial information"
HOMEPAGE="http://openmap.bbn.com/"
SRC_URI="http://openmap.bbn.com/cgi-bin/license.cgi?/${P}.zip"

LICENSE="OpenMap"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc firefox j3d seamonkey"
RESTRICT="fetch"

MY_BATIK_SLOT="1.6"
MY_COMMON_DEPS="dev-java/batik:${MY_BATIK_SLOT}
	j3d? ( dev-java/sun-java3d-bin )"

RDEPEND=">=virtual/jre-1.4.2
	firefox? ( || ( www-client/mozilla-firefox
		www-client/mozilla-firefox-bin ) )
	seamonkey? ( || ( www-client/seamonkey
		www-client/seamonkey-bin ) )
	${MY_COMMON_DEPS}"

DEPEND="app-arch/unzip
	>=virtual/jdk-1.4.2
	${MY_COMMON_DEPS}"

EANT_BUILD_TARGET="all"


src_prepare() {
	cd "${S}"
	rm -v lib/{openmap,omcorba,omsvg,omj3d}.jar
	# must keep the mil std png jar?

	epatch "${FILESDIR}"/${P}-batikpath.patch
	epatch "${FILESDIR}"/${P}-java3dpath.patch
	sed -e 's/=data\//=\/usr\/share\/openmap\/data\//' \
		-i ${PN}.properties || die "cannot sed-fix the data paths (openmap.properties)"
	sed -e 's/=data\//=\/usr\/share\/openmap\/data\//' \
		-i src/openmap/com/bbn/openmap/gui/MapWindow.java || die "cannot sed-fix the data paths (MapWindow.java)"

	local MY_BROWSER=""
	if use firefox; then
		if use seamonkey; then
			ewarn "Firefox USE flag overrides seamonkey, only set one to be specific."
		fi
		MY_BROWSER=firefox
	elif use seamonkey; then
		MY_BROWSER=seamonkey
	fi

	if [[ -n MY_BROWSER ]]; then
		einfo "Switching help browser from netscape to " $MY_BROWSER
		sed -e "s/netscape -install/$MY_BROWSER/" \
			-i openmap.properties
		sed -e "s/netscape/$MY_BROWSER/" \
			-i src/ext/edu/stanford/ejalbert/BrowserLauncher.java
		sed -e "s/netscape -install/$MY_BROWSER/" \
			-i src/openmap/com/bbn/openmap/examples/beanbox/openmap.properties
	else
		einfo "You didn't set firefox or seamonkey USE flag, so keeping netscape as help browser."
	fi

	cd lib

	# TODO: maybe svg could be turned into a USE flag as well?
	# symlink SVG / Batik jars
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-rasterizer.jar
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-svggen.jar
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-dom.jar
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-awt-util.jar
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-util.jar
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-transcoder.jar
	java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-ext.jar
	# would it be easier to do: java-pkg_jar-from batik-${MY_BATIK_SLOT} batik-all.jar

	# TODO: sun-java3d-bin equivalents are available as from-source ebuilds in java overlay as dev-java/j3core and friends
	if use j3d; then
		java-pkg_jar-from sun-java3d-bin j3dcore.jar
		java-pkg_jar-from sun-java3d-bin j3dutils.jar
		java-pkg_jar-from sun-java3d-bin vecmath.jar
	fi
}

src_install() {
	java-pkg_dojar lib/${PN}.jar
	java-pkg_dojar lib/omcorba.jar
	java-pkg_dojar lib/milStd2525_png.jar
	java-pkg_dojar lib/omsvg.jar
	use j3d && java-pkg_dojar lib/omj3d.jar
	java-pkg_dolauncher ${PN} --jar ${PN}.jar

	dodoc AUTHORS INSTALL LICENSE README
	use doc && dohtml -r doc/*

	insinto /usr/share/${PN}/lib
	doins openmap.properties

	insinto /usr/share/${PN}
	doins -r "share/data"
}