ebuild with fixed configure options and icon line in .desktop

epdfview-0.1.7.ebuild (text/plain), 999 bytes, created by Sergey Zasenko on 2009-03-14 15:38:38 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit eutils

DESCRIPTION="Lightweight PDF viewer using Poppler and GTK+ libraries."
HOMEPAGE="http://trac.emma-soft.com/epdfview/"
SRC_URI="http://trac.emma-soft.com/epdfview/chrome/site/releases/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 hppa ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="cups nls test"

COMMON_DEPEND=">=app-text/poppler-bindings-0.5.0[gtk]
	>=x11-libs/gtk+-2.6
	cups? ( >=net-print/cups-1.1 )"
DEPEND="${COMMON_DEPEND}
	>=dev-util/pkgconfig-0.9
	nls? ( sys-devel/gettext )
	test? ( dev-util/cppunit )"
RDEPEND="${COMMON_DEPEND}
	nls? ( virtual/libintl )"

src_prepare() {
	sed -i "s:Icon=\(.*\):Icon=/usr/share/${PN}/pixmaps/\1.png:" data/epdfview.desktop
}

src_configure() {
	econf \
		$(use_with cups) \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS NEWS README THANKS
}