# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils pam

DESCRIPTION="FTP layout package"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI=""

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd"
IUSE="pam avahi"

DEPEND="pam? ( virtual/pam )
	!<net-ftp/proftpd-1.2.10-r6
	!<net-ftp/pure-ftpd-1.0.20-r2
	!<net-ftp/vsftpd-2.0.3-r1
	avahi? ( net-dns/avahi )
	!<net-dns/avahi-0.6.24"

S=${WORKDIR}

check_collision() {
	[[ ! -e $1 ]] && return 0

	[[ $(head -n 1 "$1") == $(head -n 1 "$2") ]] && return 0

	eerror "   $1 exists and was not provided by ${P}"
	return 1
}

pkg_setup() {
	ebegin "Checking for possible file collisions..."

	local collide=false
	check_collision "${ROOT}etc/ftpusers" "${FILESDIR}/ftpusers" || collide=true

	if use pam ; then
		check_collision "${ROOT}etc/pam.d/ftp" "${FILESDIR}/ftp-pamd" || collide=true
	fi

	if use avahi ; then
		check_collision "${ROOT}etc/avahi/services/ftp.service" \
		"${FILESDIR}/ftp.service" || collide=true
	fi

	if ${collide} ; then
		eerror
		eerror "Those files listed above have to be removed in order to"
		eerror "install this version of ftpbase."
		eerror
		eerror "If you edited them, remember to backup and when restoring make"
		eerror " sure the first line in each file is:"
		eerror "$(head -n 1 "${FILESDIR}/ftpusers")"
		eend 1
		die "Can't be installed, files will collide"
	fi

	eend 0

	# Check if home exists
	local exists=false
	[[ -d "${ROOT}home/ftp" ]] && exists=true

	# Add our default ftp user
	enewgroup ftp 21
	enewuser ftp 21 -1 /home/ftp ftp

	# If home did not exist and does now then we created it in the enewuser
	# command. Now we have to change it's permissions to something sane.
	if [[ ${exists} == "false" && -d "${ROOT}home/ftp" ]] ; then
		chown root:ftp "${ROOT}"home/ftp
	fi
}

src_install() {
	# The ftpusers file is a list of people who are NOT allowed
	# to use the ftp service.
	insinto /etc
	doins "${FILESDIR}/ftpusers" || die

	# If avahi is enabled and available, install a file registering the ftp
	# service with it.
	if use avahi ; then
		insinto /etc/avahi/services
		doins "${FILESDIR}/ftp.service"
	fi

	# Ideally we would create the home directory here with a dodir.
	# But we cannot until bug #9849 is solved - so we kludge in pkg_postinst()

	newpamd "${FILESDIR}/ftp-pamd-include" ftp
}