vsftpd-devnet-2.1.0_p1.ebuild

vsftpd-devnet-2.1.0_p1.ebuild (text/plain), 2.77 KB, created by Kanstantsin Shautsou on 2009-03-08 17:21:21 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs

DESCRIPTION="Very Secure FTP Daemon with devnet patchset"
HOMEPAGE="http://vsftpd.beasts.org/"
SRC_URI="http://vsftpd.devnet.ru/files/${PV%_p*}/ext.${PV#*_p}/${PN%-*}-${PV%_p*}-ext${PV#*_p}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="caps pam tcpd ssl selinux xinetd"

DEPEND="caps? ( sys-libs/libcap )
	pam? ( virtual/pam )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	ssl? ( >=dev-libs/openssl-0.9.7d )"
RDEPEND="${DEPEND}
	!net-ftp/vsftpd
	net-ftp/ftpbase
	selinux? ( sec-policy/selinux-ftpd )
	xinetd? ( sys-apps/xinetd )"

S=${WORKDIR}/${PN%-*}-${PV%_p*}-ext.${PV#*_p}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Patch the source, config and the manpage to use /etc/vsftpd/
	epatch "${FILESDIR}/${PN}-2.1.0-gentoo.patch"

	# Configure vsftpd build defaults
	use tcpd && echo "#define VSF_BUILD_TCPWRAPPERS" >> builddefs.h
	use ssl && echo "#define VSF_BUILD_SSL" >> builddefs.h
	use pam || echo "#undef VSF_BUILD_PAM" >> builddefs.h

	# Ensure that we don't link against libcap unless asked
	if ! use caps ; then
		sed -i '/^#define VSF_SYSDEP_HAVE_LIBCAP$/ d' sysdeputil.c
		epatch "${FILESDIR}"/${PN}-2.1.0-dont-link-caps.patch
	fi

	# Let portage control stripping
	sed -i '/^LINK[[:space:]]*=[[:space:]]*/ s/-Wl,-s//' Makefile
}

src_compile() {
	emake CFLAGS="${CFLAGS}" CC="$(tc-getCC)" || die
}

src_install() {
	into /usr
	doman vsftpd.conf.5 vsftpd.8 || die
	dosbin vsftpd || die

	dodoc AUDIT BENCHMARKS BUGS Changelog FAQ \
		README README.security REWARD SIZE \
		SPEED TODO TUNING || die
	newdoc vsftpd.conf vsftpd.conf.example || die

	docinto security || die
	dodoc SECURITY/* || die

	insinto "/usr/share/doc/${PF}/examples" || die
	doins -r EXAMPLE/* || die

	insinto /etc/vsftpd || die
	newins vsftpd.conf vsftpd.conf.example || die

	insinto /etc/logrotate.d || die
	newins "${FILESDIR}/vsftpd.logrotate" vsftpd || die

	if use xinetd ; then
		insinto /etc/xinetd.d || die
		newins "${FILESDIR}/vsftpd.xinetd" vsftpd || die
	fi

	newinitd "${FILESDIR}/vsftpd.init" vsftpd || die

	keepdir /usr/share/vsftpd/empty
}

pkg_postinst() {
	# If we use xinetd, then we comment out listen=YES
	# so that our default config works under xinetd - fixes #78347
	if use xinetd ; then
		sed -i '/\listen=YES/s/^/#/g' "${D}"/etc/vsftpd/vsftpd.conf.example
	fi

	einfo "vsftpd init script can now be multiplexed."
	einfo "The default init script forces /etc/vsftpd/vsftpd.conf to exist."
	einfo "If you symlink the init script to another one, say vsftpd.foo"
	einfo "then that uses /etc/vsftpd/foo.conf instead."
	einfo
	einfo "Example:"
	einfo "   cd /etc/init.d"
	einfo "   ln -s vsftpd vsftpd.foo"
	einfo "You can now treat vsftpd.foo like any other service"
}