# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/swish-e/swish-e-2.4.4.ebuild,v 1.2 2007/07/13 06:13:03 mr_bones_ Exp $

inherit perl-module eutils

DESCRIPTION="Simple Web Indexing System for Humans - Enhanced"
HOMEPAGE="http://www.swish-e.org/"
SRC_URI="http://www.swish-e.org/distribution/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="doc perl pdf mp3"

DEPEND=">=sys-libs/zlib-1.1.3
	dev-libs/libxml2
	pdf?  ( app-text/poppler )
	perl? (	dev-perl/libwww-perl
			dev-perl/HTML-Parser
			dev-perl/HTML-Tagset
			dev-perl/MIME-Types
			dev-perl/HTML-Template
			dev-perl/HTML-FillInForm
			dev-perl/Template-Toolkit
			mp3? ( dev-perl/MP3-Tag )
	)"

src_unpack() {
	if has_version 'www-apps/swish-e'; then
		ewarn "Your old swish-e indexes may not be compatible with this version."
		epause 10
	fi
	unpack ${A}
	cd ${S}
	if use perl ; then 
		einfo 'Applying Perl Patches'; 
		#cp "${FILESDIR}/Makefile.PL" "${S}/perl/Makefile.PL"
		epatch ${FILESDIR}/perl-makefile-${PV}.patch
		einfo 'Done'
	fi
}

# Designed for EAPI 2 but not bumping EAPI 2 till somebody thinks its a good
# idea and it works
fake_configure() {
	cd "${S}";
	econf || die "configuration failed"
	if use perl; then
		einfo "Configuring for Perl"
		cd "${S}/perl"
		chmod u+x "${S}/swish-config"
		myconf="SWISHBINDIR=${S} SWISHIGNOREVER SWISHSKIPTEST"
		perl-module_src_configure
		einfo 'Done'
	fi
}
src_compile() {
	fake_configure
	cd "${S}"
	# XXX: is this -j1 really needed ?
	emake -j1 || die "emake failed"
	if use perl ; then
		einfo "Compiling for Perl"
		cd ${S}/perl
		chmod u+x "${S}/swish-config"
		myconf="SWISHBINDIR=${S} SWISHIGNOREVER SWISHSKIPTEST"
		perl-module_src_compile
		einfo 'Done'
	fi
}

src_install() {
	dobin src/swish-e || die "dobin failed"
	dodoc INSTALL README
	make DESTDIR="${D}" install || die

	if use doc; then
		dodir /usr/share/doc/${PF}
		cp -r html conf "${D}"/usr/share/doc/${PF} || die "cp failed"
	fi
	if use perl ; then
		einfo "Installing for Perl"
		myconf="SWISHBINDIR=${S} SWISHIGNOREVER SWISHSKIPTEST"
		cd ${S}/perl
		perl-module_src_install
		eend
	fi
}

pkg_postinst() {
	einfo "If you wish to be able to index MS Word documents, "
	einfo "emerge app-text/catdoc"
	einfo
	einfo "If you wish to be able to index MS Excel Spreadsheets,"
	einfo "emerge dev-perl/SpreadSheet-ParseExcel and"
	einfo "dev-perl/HTML-Parser"
}