release candidate

jaranalyzer-1.2.ebuild (text/plain), 1.00 KB, created by Ralph Sennhauser (RETIRED) on 2009-03-07 20:11:27 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"
JAVA_PKG_IUSE="doc source"
WANT_ANT_TASKS="ant-junit4"

inherit java-pkg-2 java-ant-2

DESCRIPTION="Dependency management utility for jar files."
HOMEPAGE="http://www.kirkk.com/main/Main/JarAnalyzer/"
SRC_URI="http://www.kirkk.com/main/zip/JarAnalyzer-src-${PV}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="test"
COMMON_DEP="dev-java/ant-core
	=dev-java/bcel-5.2*
	test? ( dev-java/junit:4 )"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"
DEPEND=">=virtual/jdk-1.4
	app-arch/unzip
	${COMMON_DEP}"

src_unpack(){
	mkdir "${S}"
	cd "${S}"
	unpack ${A}
	rm `find . -name \*.class` -R docs/

	cp "${FILESDIR}/build.xml" .

	cd "${S}/lib"
	rm -R *
	java-pkg_jar-from ant-core ant.jar
	java-pkg_jar-from bcel
	use test && java-pkg_jar-from junit-4
}

src_test() {
	eant test
}

src_install() {
	java-pkg_dojar "${PN}.jar"
	use doc && java-pkg_dojavadoc javadocs
	use source && java-pkg_dosrc src/*
}