xbmc-8.10.ebuild

xbmc-8.10.ebuild (text/plain), 6.11 KB, created by Rick Harris on 2009-03-02 10:33:00 UTC

EAPI="2"
inherit autotools eutils flag-o-matic

SRC_URI="mirror://sourceforge/${PN}/XBMC-${PV}.src.tar.gz"
DESCRIPTION="XBMC is a free and open source media-player and entertainment hub"
HOMEPAGE="http://xbmc.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="alsa autostart +debug gprof joystick opengl"
RDEPEND="joystick? ( media-libs/libsdl[joystick] )
	opengl? ( virtual/opengl )
	app-arch/bzip2
	app-arch/unrar
	app-arch/unzip
	app-i18n/enca
	>=dev-lang/python-2.4
	dev-libs/boost
	<dev-libs/fribidi-0.19.1
	dev-libs/libpcre
	dev-libs/lzo
	dev-libs/tre
	=dev-python/pysqlite-2*
	media-libs/alsa-lib[debug]
	media-libs/faac
	media-libs/fontconfig
	media-libs/freetype
	media-libs/glew
	media-libs/jasper
	media-libs/libmad
	media-libs/libsdl[alsa,X]
	media-libs/libogg
	media-libs/libvorbis
	media-libs/sdl-gfx
	media-libs/sdl-image[gif,jpeg,png]
	media-libs/sdl-mixer
	media-libs/sdl-sound
	net-misc/curl
	sys-apps/dbus
	sys-apps/hal
	sys-apps/pmount
	virtual/mysql
	x11-libs/libXinerama
	x11-libs/libXrandr
	x11-libs/libXrender"
DEPEND="${RDEPEND}
	x11-proto/xineramaproto
	dev-util/cmake
	dev-lang/nasm"
S="${WORKDIR}/XBMC"

pkg_setup() {
        if use autostart; then
		XBMC_GROUPS="video,audio,cdrom,plugdev,tty,uucp,usb"
		enewuser xbmc -1 /bin/bash /home/xbmc ${XBMC_GROUPS}
		usermod -a -G ${XBMC_GROUPS} xbmc
	fi
}

src_unpack() {
	unpack ${A}
	cd ${S}

	# Enable support for XBMC to read data DVD discs #
	# See http://xbmc.org/trac/attachment/ticket/5296/ #
	epatch "${FILESDIR}/xbmc-8.10_readsector.diff"

	for file in {configure,*.pl}; do
		find . -name "${file}" -exec chmod +x {} \;
	done

	# Prevent Mac OSX files being installed #
	rm -rf system/python/lib-osx/
	rm system/players/dvdplayer/*-osx*

        # Clean up XBMC's wrapper script
        #  - dont muck with gnome screensaver stuff, make user do it
        #  - if alsa has oss support, we want to fix the default
        sed -e '/dbus/d' \
		-e "2i$(use alsa && echo export SDL_AUDIODRIVER=alsa)" \
		-i tools/Linux/xbmc.sh.in

	# Fix XBMC's final version string showing as "exported" instead of the version number #
	# Also cleanup flags #
	sed -e "s/\$(svnversion -n .)/${PV}/g" \
		-i configure || die "Sed failed for '"${S}/configure"'"
	sed -r -e '/DEBUG_FLAGS/s:-(g|O2)::' \
		-i configure || die "Sed failed for '"${S}/configure"'"
	sed -e 's:\<strip\>:echo:' \
		-i xbmc/lib/libhdhomerun/Makefile.in || \
		die "Sed failed for '"${S}/xbmc/lib/libhdhomerun/Makefile.in"'"

	# Avoid lsb-release dependency
	sed -e 's:/usr/bin/lsb_release -d:cat /etc/gentoo-release:' \
		-i xbmc/utils/SystemInfo.cpp || \
		die "Sed failed for '"${S}/xbmc/utils/SystemInfo.cpp"'"

	# Avoid help2man
	sed -e '/HELP2MAN.*--output/s:.*:\ttouch $@:' \
		-i xbmc/lib/libcdio/libcdio/src/Makefile.in || \
		die "Sed failed for '"${S}/xbmc/lib/libcdio/libcdio/src/Makefile.in"'"

	# Tweak autotool timestamps to avoid regeneration
	find . -type f -print0 | xargs -0 touch -r configure
}

src_configure() {
	# Disable documentation generation
	export ac_cv_path_LATEX=no

	# Strip out the use of custom C{XX}FLAGS to make debugging easier for upstream #
	# This is needed regardless of whether USE="debug" is set otherwise segfaults result #
	# Tested to happen with MP3 playback when MACDll-i486-linux.so loads + fails trying to read ID3 info #
	strip-flags

	econf \
		--disable-ccache \
		$(use_enable debug) \
		$(use_enable gprof profiling) \
		$(use_enable joystick) \
		$(use_enable opengl gl) \
		|| die "Configure failed!"
}

src_compile() {
	emake || die "Make failed!"
	cd "${S}"

	if use autostart; then
		echo 'int main() {' > autologinxbmc.c
		echo '  execlp("login", "login", "-f", "xbmc", 0);' >> autologinxbmc.c
		echo '}' >> autologinxbmc.c
		$(tc-getCC) -w -o autologinxbmc autologinxbmc.c
	fi

	einfo
	einfo "Generating textures..."
	einfo
	for skin in skin/* ; do
		./tools/XBMCTex/XBMCTex -input "\"${skin}/media/\"" \
			-output "\"${skin}/media/Textures.xpr\"" || die "XBMCTex failed..."
	done

	# Fix case sensitivity
	mv media/Fonts/{a,A}rial.ttf
	mv media/{S,s}plash.png

	# Unzip web content
	cd web
	unpack ./Project_Mayhem_III_webserver_*.zip
}

src_install() {
	einstall || die "Install failed!"

	dodoc LICENSE.GPL README.linux copying.txt known_issues.txt
	rm "${D}"/usr/share/xbmc/{README.linux,LICENSE.GPL,*.txt}

	make_session_desktop "XBMC Media Center" xbmc --standalone -fs
	insinto /usr/share/applications
	doins tools/Linux/xbmc.desktop
	doicon tools/Linux/xbmc.png

	dodir /etc/env.d
        if use autostart; then
		echo 'CONFIG_PROTECT="/usr/share/xbmc/userdata /home/xbmc"' > "${D}/etc/env.d/95xbmc"

		echo '/usr/bin/xbmc' > .xinitrc
		echo 'case "`tty`" in' > .bash_profile
		echo '	*tty8) xinit -- :$(echo $[`(ls /tmp/.X?-lock 2> /dev/null) | tail -n1 | sed "s,^/tmp/.X\(.*\)-lock$,\1,"` + 1]); logout ;;' >> .bash_profile
		echo 'esac' >> .bash_profile

		insinto /home/xbmc
		doins .bash_profile
		doins .xinitrc

		exeinto /usr/sbin
		doexe autologinxbmc
	else
		echo 'CONFIG_PROTECT="/usr/share/xbmc/userdata"' > "${D}/etc/env.d/95xbmc"
        fi
}

pkg_postinst() {
	elog
	elog "Toggle fullscreen mode using the backslash key"
	elog "To access a MythTV backend, add 'myth://<mythdb_user>:<mythdb_pass>@<hostname>/'"
	elog " as a new source in the 'Videos' section"
	elog "For further documentation, visit http://xbmc.org/wiki/?title=XBMC_Online_Manual"
	elog
	elog "Details on filing bugs to upstream can be found at"
	elog "http://xbmc.org/wiki/?title=HOW-TO_Submit_a_Proper_Bug_Report"
	elog "Make sure you (re)build with the 'debug' USE flag enabled"
	elog

	if use autostart; then
		elog "You have enabled 'USE=autostart', the following needs"
		elog " to be performed to complete the installation:"
		elog "Please add the following to your /etc/inittab file"
		elog "at the end of the TERMINALS section"
		elog "c8:2345:respawn:/sbin/agetty -n -l /usr/sbin/autologinxbmc 38400 tty8"
		elog
		elog "To have the system reload /etc/inittab without rebooting,"
		elog "issue 'init q' as root"
		elog
		elog "For the security conscious, please note that this automatically"
		elog "logins the user 'xbmc' with no authentication password necessary"
		elog
	else
		elog "To have XBMC start automatically, set 'USE=autostart'"
		elog
	fi
}