weechat-9999.ebuild

weechat-9999.ebuild (text/plain), 1.45 KB, created by Tomáš Chvátal (RETIRED) on 2009-02-28 10:24:12 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit cmake-utils git

DESCRIPTION="Portable and multi-interface IRC client."
HOMEPAGE="http://weechat.flashtux.org/"
EGIT_REPO_URI="git://git.sv.gnu.org/weechat.git"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"

NETWORKS="jabber +irc"
PLUGINS="+charset +fifo +logger +relay +scripts +spell +trigger"
INTERFACES="+ncurses gtk"
SCRIPT_LANGS="lua +perl +python ruby tcl"
IUSE="${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS} doc nls +ssl"

RDEPEND="
	charset? ( virtual/libiconv )
	gtk? ( x11-libs/gtk+:2 )
	jabber? ( dev-libs/iksemel )
	lua? ( dev-lang/lua[deprecated] )
	ncurses? ( sys-libs/ncurses )
	perl? ( dev-lang/perl )
	python? ( virtual/python )
	ruby? ( dev-lang/ruby )
	ssl? ( net-libs/gnutls )
	spell? ( app-text/aspell )
	tcl? ( >=dev-lang/tcl-8.4.15 )
"
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.15 )
"

src_configure() {
	local x large_x

	for x in ${IUSE}; do
		large_x=$(echo ${x/+/} | tr [a-z] [A-Z])
		if [[ "${x/+/}" = trigger || "${x/+/}" = gtk ]]; then
			mycmakeargs="${mycmakeargs} $(cmake-utils_use_enable ${x/+/} ${large_x})"
		else
			mycmakeargs="${mycmakeargs} $(cmake-utils_use_disable ${x/+/} ${large_x})"
		fi
	done
	echo $mycmakeargs || die
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS BUGS ChangeLog FAQ NEWS README TODO || die "dodoc failed"
}