# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils rpm multilib flag-o-matic

SDK_PV=1.14.32.1

DESCRIPTION="LightScribe System Software (binary only library)."
HOMEPAGE="http://www.lightscribe.com/downloadSection/linux/index.aspx"
SRC_URI="http://download.lightscribe.com/ls/lightscribe-${PV}-linux-2.6-intel.rpm
	http://download.lightscribe.com/ls/lightscribePublicSDK-${SDK_PV}-linux-2.6-intel.rpm"

LICENSE="lightscribe lightscribeSDK"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="multilib"

DEPEND=""

RDEPEND="virtual/libc
	sys-libs/libstdc++-v3
	amd64? ( multilib? ( app-emulation/emul-linux-x86-compat ) )"

RESTRICT="mirror strip fetch"

src_unpack() {
	rpm_src_unpack
}

src_compile() { :; }

src_install() {
	has_multilib_profile && ABI="x86"

	ln -sf liblightscribe.so.1 "${WORKDIR}"/usr/lib/liblightscribe.so.0.0.1
	exeinto /opt/lightscribe/$(get_libdir)/lightscribe/updates
	doexe "${WORKDIR}"/usr/lib/lightscribe/updates/fallback.sh
	exeinto /opt/lightscribe/$(get_libdir)/lightscribe
	doexe "${WORKDIR}"/usr/lib/lightscribe/elcu.sh
	into /opt/lightscribe
	dolib.so "${WORKDIR}"/usr/lib/liblightscribe.so.*
	dosym liblightscribe.so.1 /opt/lightscribe/$(get_libdir)/liblightscribe.so
	insinto /usr/include/lightsribe
	doins -r "${WORKDIR}"/usr/include/*
	insinto /etc
	doins -r "${WORKDIR}"/etc/*
	dosed "s%/usr/lib%/opt/lightscribe/$(get_libdir)%" /etc/lightscribe.rc
	dodoc "${WORKDIR}"/usr/share/doc/*.*
	dodoc "${WORKDIR}"/usr/share/doc/lightscribe-sdk/*.*
	dodoc "${WORKDIR}"/usr/share/doc/lightscribe-sdk/docs/*
	docinto sample/lsprint
	dodoc "${WORKDIR}"/usr/share/doc/lightscribe-sdk/sample/lsprint/*
	dodir /etc/env.d
	echo "LDPATH=/opt/lightscribe/$(get_libdir)" > "${D}"/etc/env.d/80lightscribe
}

pkg_postinst() {
	einfo
	einfo "This version also support Enhanced Contrast"
	einfo "You can activate it by running:"
	einfo "/opt/lightscribe/$(get_libdir)/lightscribe/elcu.sh"
	einfo
}

pkg_nofetch() {
	einfo "Please download the appropriate Lightscribe System Software & Linux Public SDK archive's"
	einfo "( lightscribe-${PV}-linux-2.6-intel.rpm"
	einfo "  lightscribePublicSDK-${SDK_PV}-linux-2.6-intel.rpm )"
	einfo "from ${HOMEPAGE} (requires to accept license)"
	einfo
	einfo "Then put the file in ${DISTDIR}"
}