phonon-4.3.0.ebuild

phonon-4.3.0.ebuild (text/plain), 1.64 KB, created by Rick Harris on 2009-02-23 18:08:56 UTC

EAPI="2"
inherit cmake-utils kde4-functions

KDE_VERSION="4.2.0"

DESCRIPTION="KDE multimedia API"
HOMEPAGE="http://phonon.kde.org"
SRC_URI="mirror://kde/stable/${KDE_VERSION}/src/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="debug gstreamer kdeprefix +xcb +xine"

RDEPEND="
	!kde-base/phonon-xine
	!x11-libs/qt-phonon:4
	>=x11-libs/qt-test-4.4.0:4
	>=x11-libs/qt-dbus-4.4.0:4
	>=x11-libs/qt-gui-4.4.0:4
	gstreamer? (
		media-libs/gstreamer
		media-libs/gst-plugins-base
		>=x11-libs/qt-opengl-4.4.0:4
	)
	xine? (
		>=media-libs/xine-lib-1.1.15-r1[xcb?]
		xcb? ( x11-libs/libxcb )
	)
"

DEPEND="${RDEPEND}
	>=kde-base/automoc-0.9.87
"

pkg_setup() {
	if use !xine && use !gstreamer; then
		die "you must at least select one backend for phonon"
	fi

	# Make phonon "+kdeprefix" aware #
	# Note that we don't want to install phonon in the kdeprefix (a la kde4-base.eclass) #
	# as this will cause problems with multiple 4.x installations #
	if use kdeprefix; then	# Copied from kde4-base.eclass
		KDE_WANTED="${KDE_WANTED:=live}"
		export KDE_WANTED
		get_latest_kdedir
		KDEDIR="/usr/kde/${_kdedir}"
	fi
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_with gstreamer GStreamer)
		$(cmake-utils_use_with gstreamer GStreamerPlugins)
		$(cmake-utils_use_with xine Xine)"

	if use xine; then
		mycmakeargs="${mycmakeargs}
			$(cmake-utils_use_with xcb XCB)"
	else
		sed -i -e '/xine/d' \
			"${S}/CMakeLists.txt" || die "sed failed"
	fi
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	use kdeprefix && \
		dosym /usr/share/kde4/services/phononbackends ${KDEDIR}/share/kde4/services/phononbackends
}