1.4-r2 ebuild candidate

libsfml-1.4-r2.ebuild (text/plain), 973 bytes, created by Sebastian Pipping on 2009-02-20 15:04:42 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils autotools

MY_PN="SFML"

DESCRIPTION="Simple and fast multimedia library"
HOMEPAGE="http://sfml.sourceforge.net/"
SRC_URI="http://downloads.sourceforge.net/${PN}/${MY_PN}-${PV}-sdk-linux.tar.gz"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

DEPEND="media-libs/freetype
	media-libs/libsndfile
	media-libs/openal
	media-libs/jpeg
	media-libs/libpng
	media-libs/glew
	sys-libs/zlib"

RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_PN}-${PV}"

src_unpack()
{
	unpack ${A}
	cd "${S}"
	rm -v lib/*.so.*
	rm -Rf src/SFML/Graphics/{GLEW,lib{jpeg,png},zlib}
	epatch "${FILESDIR}"/${PN}-1.4-destdir-r3.patch || die "epatch failed"
	epatch "${FILESDIR}"/${PN}-1.4-deps.patch || die "epatch failed"
}

src_compile()
{
	emake || die "emake failed"
}

src_install()
{
	emake install DESTDIR="${D}" prefix=/usr || die "emake install failed"
}