Ebuild to install smolt under Gentoo

smolt-1.1.1.1.ebuild (text/plain), 2.39 KB, created by Peter GAAL on 2009-02-03 14:19:33 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit rpm python eutils

DESCRIPTION="The Fedora hardware profiler"
HOMEPAGE="https://fedorahosted.org/smolt/"
SRC_URI="http://download.fedora.redhat.com/pub/epel/5/SRPMS/${P}-1.el5.src.rpm"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="gtk"

DEPEND="
	virtual/python
	sys-devel/gettext
	gtk? ( >=dev-python/pygtk-2.10.3 )
"
RDEPEND="
	sys-apps/hal
	>=dev-python/rhpl-0.213
	>=dev-python/urlgrabber-3.0.0
	>=dev-python/simplejson-1.7.1
"

src_unpack() {
	rpm_src_unpack
	cd ${S}
	epatch "${FILESDIR}/client.patch" 
	! use gtk \
	&& epatch "${FILESDIR}/headless.patch" 
}

S="${S}/client"
SMOLT='/usr/share/smolt/client'
UUID='/etc/smolt/hw-uuid'

src_install() {
	emake install DESTDIR="${D}" || die "Install failed"

	dosym ${SMOLT}/sendProfile.py /usr/bin/smoltSendProfile \
	|| die "dosym sendProfile"
	dosym ${SMOLT}/deleteProfile.py /usr/bin/smoltDeleteProfile \
	|| die "dosym deleteProfile"
	dosym /etc/smolt/config.py ${SMOLT}/config.py \
	|| die "dosym config.py"

	exeinto /usr/share/doc/${PF}
	exeopts -m0744
	doexe "${FILESDIR}/smolt_monthly.sh" || die "doexe smolt_monthly.sh"

	insinto ${SMOLT}
	doins "makeuuid.py" || die "doins makeuuid.py"

	if use gtk; then
		doicon icons/smolt-icon-48.png
		dosed "s:smolt.png:smolt-icon-48.png:" /usr/share/applications/fedora-smolt.desktop \
		|| die 'dosed'
		dosym ${SMOLT}/smoltGui.py /usr/bin/smoltGui \
		|| die "dosym smoltGui"
	fi

	cd man
	doman smoltSendProfile.1 smoltDeleteProfile.1 || die "doman"
	if use gtk; then
		doman smoltGui.1 || die "doman smoltGui"
	fi

	cd ../..
	dodoc README doc/PrivacyPolicy || die "dodoc"
	newinitd "${FILESDIR}"/${PN}-init.d ${PN} || die "newinitd"
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"/usr/share/${PN}

	if ! [ -f ${UUID} ]; then
		python "${ROOT}"/"${SMOLT}"/makeuuid.py --output="${ROOT}"/"${UUID}" \
		|| die "makeuuid failed"
	fi

	echo
	elog "Call smoltSendProfile as root in order to initialize your profile."
	echo
	elog "You can withdraw it from the server if you wish to with"
	elog "   smoltDeleteProfile any time later on."
	echo

	if use gtk && has_version "<virtual/python-2.5"; then
		elog "If you want to view your profile on the web from within smoltGui,"
		elog "you should have a link mozilla-firefox -> firefox in your path."
		echo
	fi
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}
}