Fully working ebuild for widelands-0.0.13

widelands-0.0.13.ebuild (text/plain), 2.73 KB, created by Eric "me262" Mason on 2009-01-26 19:31:03 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/widelands/widelands-0.0.13.ebuild,v 1.3 2008/09/01 20:19:27 mr_bones_ Exp $

inherit eutils flag-o-matic toolchain-funcs versionator games

MY_PV=$(get_version_component_range 3)
DESCRIPTION="A game similar to Settlers 2"
HOMEPAGE="http://www.widelands.org/"

# Build 13 breaks previous naming conventions (used to be widelands-build-12-source.tar.bz2)
SRC_URI="mirror://sourceforge/${PN}/Widelands-Build${MY_PV}-src.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls"

RDEPEND="media-libs/libsdl
	media-libs/sdl-image
	>=media-libs/sdl-mixer-1.2.6
	media-libs/sdl-net
	>=media-libs/sdl-ttf-2.0
	media-libs/sdl-gfx
	media-libs/libpng
	>=dev-libs/boost-1.33
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	>=dev-util/scons-1.0"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	
	# build 13 breaks standard unpacking: creates widelands-b13
	mv "${WORKDIR}/widelands-b13" "${S}"
	
	cd "${S}"
	
	# per comment 3 in bug #249396 scons works without patching
        # makefile is unsupported, perhaps even broken
	# rm -f $(find . -name SConscript)

	# when build=release, scons strips the binary, we'll do that ourselves
	epatch "${FILESDIR}"/${P}-build-dont_prestrip_binary.patch

	sed -i 's:__ppc__:__PPC__:' src/s2map.cc \
		|| die "sed s2map.cc failed"
	sed -i "s:/usr/share/games:${GAMES_DATADIR}:" src/wlapplication.cc \
		|| die "sed wlapplication.cc failed"
	sed -i "s:/l/WiLa/Setup:${GAMES_DATADIR}/${PN}:" src/config.h.default \
		|| die "sed config.h.default failed"
}

src_compile() {
	filter-flags -fomit-frame-pointer
	
	# makefile isn't supported anymore - using scons
	# emake CXX=$(tc-getCXX) all || die "emake failed"
	
	scons \
                build=release \
		build_id=${PVR} \
                extra_compile_flags="${CFLAGS}" \
		install_prefix=${D}/usr \
		bindir=${GAMES_BINDIR} \
		datadir=${GAMES_DATADIR}/widelands \
		localedir=/usr/share/locale || die "scons failed"
	
	if use nls ; then
		utils/buildlocale.py || die "buildlocale.py failed"
	fi
}

src_install() {
	# attempts to install to live filesystem, can't have that.
	# will old method from 0.0.12 ebuild work?
	# scons install || die "scons install failed"
		
	dogamesbin ${PN} || die "dogamesbin failed"

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r campaigns fonts maps music pics sound tribes txts worlds \
		|| die "doins failed"

	insinto "${GAMES_DATADIR}"/${PN}/locale
	local d
	for d in locale/* ; do
		if [[ -d ${d} ]] ; then
			doins -r ${d} || die "doins ${d} failed"
		fi
	done

	newicon pics/wl-ico-48.png ${PN}.png
	make_desktop_entry ${PN} Widelands

	dodoc ChangeLog CREDITS
	prepgamesdirs
}