ebuild for nvidia-cuda-toolkit-2.1

nvidia-cuda-toolkit-2.1.ebuild (text/plain), 1.57 KB, created by Joshua Anderson on 2009-01-16 04:03:10 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/nvidia-cuda-toolkit/nvidia-cuda-toolkit-2.0.ebuild,v 1.1 2008/10/18 13:15:20 spock Exp $

inherit eutils

DESCRIPTION="NVIDIA CUDA Toolkit"
HOMEPAGE="http://developer.nvidia.com/cuda"

BASE_URI="http://developer.download.nvidia.com/compute/cuda/2_1/toolkit/cudatoolkit"
SRC_URI="amd64? ( ${BASE_URI}_${PV}_linux64_suse10.3.run )
	x86? ( ${BASE_URI}_${PV}_linux32_suse10.3.run )"

LICENSE="NVIDIA"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

DEPEND=""
RESTRICT="strip"

S="${WORKDIR}"

src_unpack() {
	unpack_makeself
}

src_install() {
	local DEST=/opt/cuda

	# don't use lib32 or lib64 directories
	unset ABI

	into ${DEST}
	dobin bin/*
	dolib lib/*

	chmod a-x "${D}/${DEST}/bin/nvcc.profile"

	# doman does not respect DESTTREE
	insinto ${DEST}/man/man1
	doins man/man1/*
	insinto ${DEST}/man/man3
	doins man/man3/*
	prepman ${DEST}

	insinto ${DEST}/include
	doins include/*.h
	insinto ${DEST}/include/crt
	doins include/crt/*.h

	insinto ${DEST}/src
	doins src/*

	into ${DEST}/open64
	dobin open64/bin/*
	libopts -m0755
	dolib open64/lib/*

	if use doc ; then
		insinto ${DEST}/doc
		doins doc/*
	fi

	cat > "${T}/env" << EOF
PATH=${DEST}/bin
ROOTPATH=${DEST}/bin
LDPATH=${DEST}/lib
MANPATH=${DEST}/man
EOF
	newenvd "${T}/env" 99cuda
}

pkg_postinst() {
	elog "If you want to natively run the code generated by CUDA, you will need"
	elog ">=x11-drivers/nvidia-drivers-180.22."
	elog ""
	elog "Run '. /etc/profile' before using the CUDA toolkit. "
}