[patch] gammu-1.22.1.ebuild

gammu-1.22.1.ebuild.diff (text/plain), 2.12 KB, created by Jimmy.Jazz on 2009-01-12 21:22:31 UTC

--- ./app-mobilephone/gammu/gammu-1.22.1.ebuild	1970-01-01 01:00:00.000000000 +0100
+++ local/overlay/./app-mobilephone/gammu/gammu-1.22.1.ebuild	2009-01-09 17:01:42.000000000 +0100
@@ -0,0 +1,65 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/gammu/gammu-1.21.0.ebuild,v 1.1 2008/11/02 12:46:58 mrness Exp $
+
+inherit cmake-utils
+
+DESCRIPTION="a fork of the gnokii project, a tool to handle your cellular phone"
+HOMEPAGE="http://www.gammu.org"
+SRC_URI="ftp://dl.cihar.com/gammu/releases/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug bluetooth irda mysql postgres nls"
+
+RDEPEND="bluetooth? ( >=net-wireless/bluez-4.26 )
+	mysql? ( virtual/mysql )
+	postgres? ( virtual/postgresql-server )
+	dev-util/dialog"
+DEPEND="${RDEPEND}
+	irda? ( virtual/os-headers )
+	nls? ( sys-devel/gettext )
+	dev-util/cmake"
+
+# sys-devel/gettext is needed for creating .mo files
+# Supported languages and translated documentation
+# Be sure all languages are prefixed with a single space!
+MY_AVAILABLE_LINGUAS=" cs de es id it pl ru"
+IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"
+
+src_unpack() {
+	unpack ${A}
+
+	pushd "${S}"/locale || die "locale directory not found"
+	local lang support_linguas=no
+	for lang in ${MY_AVAILABLE_LINGUAS} ; do
+		if use linguas_${lang} ; then
+			support_linguas=yes
+			break
+		fi
+	done
+	# install all languages when all selected LINGUAS aren't supported
+	if [ "${support_linguas}" = "yes" ]; then
+		for lang in ${MY_AVAILABLE_LINGUAS} ; do
+			if ! use linguas_${lang} ; then
+				sed -i -e "/^[[:space:]]*${lang}[[:space:]]*$/d" CMakeLists.txt
+			fi
+		done
+	fi
+	popd
+}
+
+src_compile() {
+	# debug flag is used inside cmake-utils.eclass
+	local mycmakeargs="$(cmake-utils_use_with bluetooth Bluez) \
+		$(cmake-utils_use_with irda IrDA) \
+		$(cmake-utils_use_with mysql MySQL) \
+		$(cmake-utils_use_with postgres Postgres) \
+		-DENABLE_SHARED=ON"
+	cmake-utils_src_compile
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${WORKDIR}"/${PN}_build/common cmake-utils_src_test
+}