# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.13.ebuild,v 1.2 2008/10/21 00:05:52 betelgeuse Exp $

EAPI=2

inherit eutils libtool autotools flag-o-matic

DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://0pointer.de/lennart/projects/pulseaudio/"
SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"

LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc64 ~sparc ~x86"
IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome bluetooth policykit asyncns +glib nls"

RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libXau x11-libs/libXdmcp )
	caps? ( sys-libs/libcap )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
	alsa? ( >=media-libs/alsa-lib-1.0.17-r1 )
	glib? ( >=dev-libs/glib-2.4.0 )
	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
	>=dev-libs/liboil-0.3.0
	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
	tcpd? ( sys-apps/tcp-wrappers )
	lirc? ( app-misc/lirc )
	dbus? ( >=sys-apps/dbus-1.0.0 )
	gnome? ( >=gnome-base/gconf-2.4.0 )
	hal? (
		>=sys-apps/hal-0.5.7
		>=sys-apps/dbus-1.0.0
	)
	app-admin/eselect-esd
	bluetooth? (
		>=net-wireless/bluez-libs-3
		>=sys-apps/dbus-1.0.0
	)
	policykit? ( sys-auth/policykit )
	asyncns? ( net-libs/libasyncns )
	>=media-libs/audiofile-0.2.6-r1
	>=media-libs/speex-1.2_beta
	>=media-libs/libsndfile-1.0.10
	>=dev-libs/liboil-0.3.6
	sys-libs/gdbm
	|| ( sys-apps/openrc >=sys-apps/baselayout-2.0_rc5 )
	>=sys-devel/libtool-1.5.24" # it's a valid RDEPEND, libltdl.so is used

# Remove autoconf when >=2.62 stable and pulled in by autotools.eclass
DEPEND="${RDEPEND}
	>=sys-devel/autoconf-2.62
	X? ( x11-proto/xproto )
	dev-libs/libatomic_ops
	dev-util/pkgconfig
	|| ( dev-util/unifdef sys-freebsd/freebsd-ubin )
	nls? ( sys-devel/gettext dev-util/intltool )"

# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez-utils dep is for the bluetooth init.d script
RDEPEND="${RDEPEND}
	gnome-extra/gnome-audio
	alsa? ( media-sound/alsa-utils )
	bluetooth? ( >=net-wireless/bluez-utils-3 )"

pkg_setup() {
	enewgroup audio 18 # Just make sure it exists
	enewgroup realtime
	enewgroup pulse-access
	enewgroup pulse
	enewuser pulse -1 -1 /var/run/pulse pulse,audio
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Avoid building - and especially linking - test programs
	# outside of make check
	sed -i -e 's:noinst_PROGRAMS:check_PROGRAMS:' \
		"${S}/src/Makefile.am"
	epatch "${FILESDIR}/${PV}/0001-Initialize-exit_idle_time-to-1-instead-of-0-when-i.patch"
	epatch "${FILESDIR}/${PV}/0002-Unload-module-bluetooth-device-if-the-remote-device.patch"
	epatch "${FILESDIR}/${PV}/0003-instead-of-resetting-virtual_volume-unconditionally.patch"
	epatch "${FILESDIR}/${PV}/0004-use-pa_channel_map_init_extend-instead-of-pa_chann.patch"
	epatch "${FILESDIR}/${PV}/0005-if-the-channel-map-was-modified-due-to-PA_SINK_INPUT.patch"
	epatch "${FILESDIR}/${PV}/0006-define-0dB-in-PA-as-maximum-amplification.patch"
	epatch "${FILESDIR}/${PV}/0007-Fix-a-potential-C-C99-ism-add-a-log-message-on-er.patch"
	epatch "${FILESDIR}/${PV}/0008-Fix-two-typos-that-broke-tunnels.patch"
	epatch "${FILESDIR}/${PV}/0009-properly-remove-dbus-matches-an-filters-when-unloadi.patch"
	epatch "${FILESDIR}/${PV}/0010-Fix-possible-invalid-read-while-attempting-to-load-m.patch"
	epatch "${FILESDIR}/${PV}/0011-always-check-for-libtool-prefix-binary-name-to-avoid.patch"
	epatch "${FILESDIR}/${PV}/0012-Fix-spelling-of-privilige.patch"
	epatch "${FILESDIR}/${PV}/0013-Make-missing-git-changelog.perl-non-fatal.patch"
	epatch "${FILESDIR}/${PV}/0014-fix-invalid-validity-check.patch"
	epatch "${FILESDIR}/${PV}/0015-convert-argument-to-boolean-int-in-PA_UNLIKELY-too.patch"
	epatch "${FILESDIR}/${PV}/0016-include-log.h-near-the-end-so-that-macro.h-can-be-in.patch"
	epatch "${FILESDIR}/${PV}/0017-Try-to-catch-certain-driver-errors.patch"
	epatch "${FILESDIR}/${PV}/0018-make-the-debug-trap-macro-a-proper-macro-in-macro.h.patch"
	epatch "${FILESDIR}/${PV}/0019-don-t-set-the-volume-of-pacat-unless-it-is-explicitl.patch"
	epatch "${FILESDIR}/${PV}/0020-warn-if-ALSA-wakes-us-up-and-there-is-actually-nothi.patch"
	epatch "${FILESDIR}/${PV}/0021-fix-build.patch"
	epatch "${FILESDIR}/${PV}/0022-make-sure-to-use-64bit-rounding-even-on-32bit-machin.patch"
	epatch "${FILESDIR}/${PV}/0023-make-shm-marker-architecture-independant-patch-from.patch"
	epatch "${FILESDIR}/${PV}/0024-Make-sure-libpulse-never-gets-unloaded.patch"
	eautoreconf
	elibtoolize
}

src_configure() {
	# To properly fix CVE-2008-0008
	append-flags -UNDEBUG

	econf \
		--enable-largefile \
		$(use_enable glib) \
		--disable-solaris \
		$(use_enable asyncns) \
		$(use_enable oss) \
		$(use_enable alsa) \
		$(use_enable lirc) \
		$(use_enable tcpd tcpwrap) \
		$(use_enable jack) \
		$(use_enable lirc) \
		$(use_enable avahi) \
		$(use_enable hal) \
		$(use_enable dbus) \
		$(use_enable gnome gconf) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable bluetooth bluez) \
		$(use_enable policykit polkit) \
		$(use_with caps) \
		$(use_with X x) \
		--disable-ltdl-install \
		--localstatedir=/var \
		--with-realtime-group=realtime \
		--disable-per-user-esound-socket \
		|| die "econf failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "make install failed"

	newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio

	use_define() {
		local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}

		use "$1" && echo "-D$define" || echo "-U$define"
	}

	unifdef $(use_define hal) \
		$(use_define avahi) \
		$(use_define alsa) \
		$(use_define bluetooth) \
		"${FILESDIR}/pulseaudio.init.d-4" \
		> "${T}/pulseaudio"

	# Specific fix for 0.9.13, drop at .14!
	sed -i -e '/start-stop-daemon --start/s:$: --exit-idle-time=-1:' \
		"${T}"/pulseaudio

	doinitd "${T}/pulseaudio"

	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"

	dohtml -r doc
	dodoc README

	# this should fix system daemon startup #233789
	cp "${D}/etc/pulse/default.pa" "${D}/etc/pulse/system.pa"

	# Create the state directory
	diropts -o pulse -g pulse -m0755
	keepdir /var/run/pulse

	find "${D}" -name '*.la' -delete
}

pkg_postinst() {
	elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
	elog "This support is enabled by starting the pulseaudio init.d ."
	elog "To be able to access that you need to be in the group pulse-access."
	elog "For more information about system-wide support, please refer to"
	elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
	if use gnome; then
		elog
		elog "By enabling gnome USE flag, you enabled gconf support. Pleaes note"
		elog "that you might need to remove the gnome USE flag or disable the"
		elog "gconf module on /etc/pulse/default.pa to be able to use PulseAudio"
		elog "with a system-wide instance."
	fi
	elog
	elog "To use the ESounD wrapper while using a system-wide daemon, you also"
	elog "need to enable auth-anonymous for the esound-unix module, or to copy"
	elog "/var/run/pulse/.esd_auth into each home directory."
	elog
	elog "If you want to make use of realtime capabilities of PulseAudio"
	elog "you should follow the realtime guide to create and set up a realtime"
	elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
	elog "Make sure you also have baselayout installed with pam USE flag"
	elog "enabled, if you're using the rlimit method."
	if use bluetooth; then
		elog
		elog "The BlueTooth proximity module is not enabled in the default"
		elog "configuration file. If you do enable it, you'll have to have"
		elog "your BlueTooth controller enabled and inserted at bootup or"
		elog "PulseAudio will refuse to start."
		elog
		elog "Please note that the BlueTooth proximity module seems itself"
		elog "still experimental, so please report to upstream if you have"
		elog "problems with it."
	fi
	if use alsa; then
		local pkg="media-plugins/alsa-plugins"
		if has_version ${pkg} && ! built_with_use --missing false ${pkg} pulseaudio; then
			elog
			elog "You have alsa support enabled so you probably want to install"
			elog "${pkg} with pulseaudio support to have"
			elog "alsa using applications route their sound through pulseaudio"
		fi
	fi

	eselect esd update --if-unset
}