Updated ebuild for RC3

qutecom-2.2_rc3.ebuild (text/plain), 1.60 KB, created by fatty on 2008-12-24 14:11:52 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit cmake-utils eutils

MY_P=${P/_rc/-RC}

DESCRIPTION="An open source softphone"
HOMEPAGE="http://www.qutecom.com/"
SRC_URI="http://www.qutecom.com/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="alsa debug oss pidgin portaudio xv"

DEPEND=">=dev-libs/boost-1.34
	dev-libs/glib
	dev-libs/openssl
	alsa? ( media-libs/alsa-lib )
	media-libs/libsamplerate
	media-libs/libsndfile
	portaudio? ( >=media-libs/portaudio-19_pre )
	media-libs/speex
	pidgin? ( net-im/pidgin )
	>=media-video/ffmpeg-0.4.9_p20080326
	net-libs/gnutls
	>=net-libs/libosip-3
	net-misc/curl
	|| ( x11-libs/libX11 virtual/x11 )
	|| ( ( x11-libs/qt-gui:4 x11-libs/qt-svg:4 ) =x11-libs/qt-4.3* )
	xv? ( x11-libs/libXv )"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}_googlebreakpad_64.patch
	epatch "${FILESDIR}"/${PN}_pixertool_ffmpeg.patch
	epatch "${FILESDIR}"/${PN}_presentation_install.patch
	epatch "${FILESDIR}"/${PN}_wifo_phapi.patch
}

src_compile() {
	EXTRA_ECONF=" \
		-DLIBPURPLE_INTERNAL=OFF \
		$(cmake-utils_use_enable portaudio PORTAUDIO_SUPPORT) \
		$(cmake-utils_use_enable alsa PHAPI_AUDIO_ALSA_SUPPORT) \
		$(cmake-utils_use_enable oss PHAPI_AUDIO_OSS_SUPPORT) \
		$(cmake-utils_use_enable xv WENGOPHONE_XV_SUPPORT) "

	cmake-utils_src_configureout
	cmake-utils_src_make
}

src_install() {
	cmake-utils_src_install
	domenu wengophone/res/qutecom.desktop || die "domenu failed"
	doicon wengophone/res/wengophone_64x64.png || die "doicon failed"
}