nspr-4.7.3-r1.ebuild

nspr-4.7.3-r1.ebuild (text/plain), 3.38 KB, created by Nathan Caldwell on 2008-12-22 21:07:41 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/nspr-4.7.3.ebuild,v 1.2 2008/11/15 18:31:56 armin76 Exp $

inherit eutils multilib toolchain-funcs flag-o-matic

DESCRIPTION="Netscape Portable Runtime"
HOMEPAGE="http://www.mozilla.org/projects/nspr/"
SRC_URI="ftp://ftp.mozilla.org/pub/mozilla.org/nspr/releases/v${PV}/src/${P}.tar.gz"

LICENSE="|| ( MPL-1.1 GPL-2 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="ipv6 debug multilib"

EMULTILIB_PKG="true"

DEPEND=">=dev-db/sqlite-3.5"

pkg_setup() {
    # try to turn off distcc and ccache for people that have a problem with it
    export DISTCC_DISABLE=1
    export CCACHE_DISABLE=1
}

setup_env() {
    # workaround for users having FEATURES=ccache set, as ccache doesn't, play
    # nice to multilib builds (see bug 206822)
    filter-flags -DABI=*
    append-flags -DABI=${ABI}
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	mkdir build inst
	epatch "${FILESDIR}"/${PN}-4.6.1-config.patch
	epatch "${FILESDIR}"/${PN}-4.6.1-config-1.patch
	epatch "${FILESDIR}"/${PN}-4.6.1-lang.patch
	epatch "${FILESDIR}"/${PN}-4.7.0-prtime.patch

	# Respect LDFLAGS
	sed -i -e 's/\$(MKSHLIB) \$(OBJS)/\$(MKSHLIB) \$(LDFLAGS) \$(OBJS)/g' \
		mozilla/nsprpub/config/rules.mk
}

src_compile() {
    if [[ -z ${OABI} ]] && has_multilib_profile; then
        einfo "Building multilib ${PN} for ABIs: $(get_install_abis)"
        OABI=${ABI}
        for ABI in $(get_install_abis); do
            export ABI=${ABI}
            src_compile
        done
        ABI=${OABI}
        return
    fi

    myconf=""
    
    cd "${S}"/build
    
    ABI=${ABI:-default}

    setup_env

    mkdir abi-${ABI}
    cd abi-${ABI}

	case ${ABI} in
	    *amd64*) myconf="${myconf} --enable-64bit";;
	    *) ;;
	esac

	if use ipv6; then
		myconf="${myconf} --enable-ipv6"
	fi

	myconf="${myconf} --libdir=/usr/$(get_libdir)/nspr \
		--enable-system-sqlite"

	ECONF_SOURCE="../../mozilla/nsprpub" econf \
		$(use_enable debug) \
		${myconf} || die "econf for ABI ${ABI} failed"
	make CC="$(tc-getCC)" CXX="$(tc-getCXX)" || die "make for ABI ${ABI} failed"
}

src_install () {
    MINOR_VERSION=7
    
    dodir /etc/env.d
    
    for ABI in $(get_install_abis); do
        # Their build system is royally fucked, as usual
        cd "${S}"/build/abi-${ABI}
        emake DESTDIR="${D}" install || die "emake install for ABI ${ABI} failed."

        cd "${D}"/usr/$(get_libdir)/nspr
        for file in *.so; do
            mv ${file} ${file}.${MINOR_VERSION}
            ln -s ${file}.${MINOR_VERSION} ${file}
        done
        # cope with libraries being in /usr/lib/nspr
        echo "LDPATH=/usr/$(get_libdir)/nspr" > "${D}/etc/env.d/08nspr-${ABI}"

        # install nspr-config
        dobin "${S}"/build/abi-${ABI}/config/nspr-config

        # create pkg-config file
        insinto /usr/$(get_libdir)/pkgconfig/
        doins "${S}"/build/abi-${ABI}/config/nspr.pc

        # Remove stupid files in /usr/bin
        rm "${D}"/usr/bin/{prerr.properties,nspr.pc}
    done
}

pkg_preinst() {
    for ABI in $(get_install_abis); do
        preserve_old_lib /usr/$(get_libdir)/nspr/lib{nspr,plc,plds}4.so.6
    done
}

pkg_postinst() {
    for ABI in $(get_install_abis); do
        preserve_old_lib_notify /usr/$(get_libdir)/nspr/lib{nspr,plc,plds}4.so.6
    done
}