# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gephex/gephex-0.4.3.ebuild,v 1.12 2007/11/27 12:43:39 zzam Exp $

EAPI=1

inherit autotools eutils

DESCRIPTION="GePhex is a modular video effect framework."
HOMEPAGE="http://www.gephex.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="aalib alsa -ffmpeg joystick mmx mpeg opengl oss png sdl v4l"

DEPEND=">=x11-libs/qt-4.1
	sdl? ( media-libs/libsdl
		media-libs/sdl-image
		media-libs/sdl-ttf )
	png? ( media-libs/libpng )
	alsa? ( media-libs/alsa-lib )
	aalib?	( >=media-libs/aalib-1.4_rc4-r2 )
	opengl? ( virtual/opengl )
	mpeg? ( media-libs/libmpeg3 )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-gcc43.patch \
		"${FILESDIR}"/${P}-libmpeg3.patch
	eautoreconf
}

src_compile() {
	econf \
		$(use_enable mmx) \
		$(use_with opengl GL) \
		$(use_with sdl SDL) \
		$(use_with sdl SDL_IMAGE) \
		$(use_with sdl SDL_TTF) \
		--without-AVIFILE \
		$(use_with mpeg MPEG3) \
		$(use_with png LIBPNG) \
		$(use_with aalib AALIB) \
		$(use_with alsa ASOUNDLIB) \
		$(use_with v4l V4L) \
		$(use_with oss OSS) \
		$(use_with joystick LINUX_JOYSTICK) \
		$(use_with ffmpeg FFMPEG)
	
	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	ewarn "This application is using a internal copy of ffmpeg, which"
	ewarn "might be outdated and have open security issues."
}