proposed ebuilr

phpMyProxy-1.0.3.ebuild (text/plain), 1.17 KB, created by Gokdeniz Karadag on 2008-11-30 19:19:20 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit webapp depend.php 

MY_P=${PN}_${PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="phpMyProxy is a web-based proxy script in PHP"
HOMEPAGE="http://www.phpmyproxy.com/"
# Upstream hosts source files as an attachment in a _password protected forum_
SRC_URI="http://www.ceng.metu.edu.tr/~gokdeniz/gentoo/${MY_P}.zip"

LICENSE="GPL-3"
KEYWORDS="~x86"
IUSE=""

DEPEND="app-arch/unzip"
RDEPEND=""

need_php_httpd

pkg_setup() {
	webapp_pkg_setup
	require_php_with_use curl
}

src_install() {
	webapp_src_preinst

	dodoc README.txt TODO.txt CHANGELOG.txt || die "Cannot copy documentation"

	insinto "${MY_HTDOCSDIR}"
	doins -r curl_log.txt index.php proxy.config.php lang themes \
		|| die "Cannot copy program files"
	keepdir "${MY_HTDOCSDIR}"/cookies || die "Cannot create cookies directory"

	webapp_serverowned "${MY_HTDOCSDIR}"/cookies
	webapp_serverowned "${MY_HTDOCSDIR}"/curl_log.txt

	webapp_configfile "${MY_HTDOCSDIR}"/proxy.config.php

	#webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	#webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt

	webapp_src_install
}