# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="A GTK+ subtitle editing tool"
HOMEPAGE="http://home.gna.org/subtitleeditor/"
SRC_URI="http://download.gna.org/subtitleeditor/${PV%.*}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug esd gconf opengl oss sdl spell xv x-noxv"

RDEPEND=">=x11-libs/gtk+-2.12
	>=dev-cpp/gtkmm-2.12
	>=dev-cpp/glibmm-2.16.3
	>=dev-cpp/libglademm-2.4
	>=dev-cpp/libxmlpp-2.10
	opengl? ( >=dev-cpp/gtkglextmm-1.2 )
	>=media-libs/gstreamer-0.10
	>=media-libs/gst-plugins-good-0.10
	>=media-plugins/gst-plugins-pango-0.10
	>=media-plugins/gst-plugins-ffmpeg-0.10
	alsa? ( >=media-plugins/gst-plugins-alsa-0.10 )
	esd? ( >=media-plugins/gst-plugins-esd-0.10 )
	gconf? ( >=media-plugins/gst-plugins-gconf-0.10 )
	oss? ( >=media-plugins/gst-plugins-oss-0.10 )
	sdl? ( >=media-libs/gst-plugins-bad-0.10 )
	xv? ( >=media-plugins/gst-plugins-xvideo-0.10 )
	x-noxv? ( >=media-plugins/gst-plugins-x-0.10 )
	spell? ( >=app-text/enchant-1.1.0 )"

DEPEND="${RDEPEND}
	dev-util/intltool
	dev-util/pkgconfig"

src_compile() {
	intltoolize --copy --force --automake || die "intltoolize failed"
	export GST_REGISTRY="${T}/home/registry.cache.xml"
	# NOTE 'enchant-support'-switch seems to be removed from 0.26.
	# Configure just checks the existence of enchant and builds the
	# support if present.
	econf \
		$(use_enable debug) \
		$(use_enable opengl gl) \
		|| die "configure failed"
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS NEWS README TODO
}