# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit distutils python

DESCRIPTION="Elisa is a media center written in Python using GStreamer"
HOMEPAGE="http://elisa.fluendo.com/"
SRC_URI="http://elisa.fluendo.com/static/download/${PN}/${P}.tar.gz"

RESTRICT="nomirror"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~ppc ~x86"
IUSE="doc"

RDEPEND=">=dev-lang/python-2.5
	dev-python/celementtree
	dev-python/gnome-python-extras
	dev-python/gst-python
	dev-python/imaging
	dev-python/pigment-python
	dev-python/pycairo
	dev-python/pyopenssl
	dev-python/pygtk
	dev-python/pysqlite
	dev-python/pyxdg
	dev-python/setuptools
	dev-python/tagpy
	>=dev-python/twisted-2.2
	dev-python/twisted-web
	dev-python/twisted-web2
	media-fonts/freefont-ttf
	media-fonts/liberation-fonts
	media-libs/gstreamer
	media-plugins/gst-plugins-a52dec
	media-plugins/gst-plugins-alsa
	media-plugins/gst-plugins-faad
	media-plugins/gst-plugins-ffmpeg
	media-plugins/gst-plugins-flac
	media-plugins/gst-plugins-jpeg
	media-plugins/gst-plugins-libpng
	media-plugins/gst-plugins-libvisual
	media-plugins/gst-plugins-mpeg2dec
	media-plugins/gst-plugins-ogg
	media-plugins/gst-plugins-pango
	media-plugins/gst-plugins-soup
	media-plugins/gst-plugins-theora
	media-plugins/gst-plugins-vorbis
	media-plugins/gst-plugins-x
	media-plugins/gst-plugins-xvideo
	media-plugins/libvisual-plugins:0.4
	x11-misc/xdg-user-dirs
	"
DEPEND="${DEPEND}
	dev-util/pkgconfig"
PDEPEND=">=media-plugins/elisa-plugins-good-${PV}
	>=media-plugins/elisa-plugins-bad-${PV}
	>=media-plugins/elisa-plugins-ugly-${PV}"

DOCS="AUTHORS COPYING FAQ FIRST_RUN LICENSE.GPL NEWS README"

pkg_setup() {
	addpredict "/root/.gstreamer-0.10"
}

src_install() {
	# If no locale has been set via $LC_ALL, $LANG or $LANGUAGE #
	# elisa will fail, so workaround by forcibly choosing one #
	# Such is the case when we don't execute elisa from a terminal #
	# Also disable StartupNotify as it doesn't get a signal back saying elisa has started, #
	# so notification icon continues to bounce merrily away long into the app. having started #
	for desk_file in {elisa.desktop,elisa-mobile.desktop}; do
		sed -e 's/Exec=elisa/Exec=LC_ALL=`locale -a | grep -vE "C|POSIX" | head -n1` elisa/' \
			-i ${S}/data/${desk_file} || \
				die "Sed failed for ${S}/data/${desk_file}"
		sed -e 's/StartupNotify=true/StartupNotify=false/' \
			-i ${S}/data/${desk_file} || \
				die "Sed failed for ${S}/data/${desk_file}"
	done

	distutils_src_install

	doman docs/*.1
	rm docs/*.1
	if use doc; then
		dodoc docs/*
		docinto api; dodoc docs/api/*
	fi
}