Ebuild to install smolt under Gentoo

smolt-1.1.1.1.ebuild (text/plain), 2.19 KB, created by Peter GAAL on 2008-11-23 16:18:08 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit rpm python eutils

DESCRIPTION="The Fedora hardware profiler"
HOMEPAGE="https://fedorahosted.org/smolt/"
SRC_URI="http://download.fedora.redhat.com/pub/epel/5/SRPMS/${P}-1.el5.src.rpm"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="
	virtual/python
	sys-devel/gettext
	>=dev-python/pygtk-2.10.3
"
RDEPEND="
	sys-apps/hal
	>=dev-python/rhpl-0.213
	>=dev-python/urlgrabber-3.0.0
	>=dev-python/simplejson-1.7.1
"

src_unpack() {
	rpm_src_unpack
	cd ${S}
	epatch "${FILESDIR}/client.patch" 
}

S="${S}/client"
MYDIR='/usr/share/smolt/client'
MYFILE='/etc/smolt/hw-uuid'

src_install() {
	emake install DESTDIR="${D}" || die "Install failed"
	if ! [ -f ${MYFILE} ]; then
		# A call 'make uuid' would fail at this point, hence
		python makeuuid.py --output="${D}/${MYFILE}" || die "makeuuid failed"
	fi

	doicon icons/smolt-icon-48.png
	dosed "s:smolt.png:smolt-icon-48.png:" /usr/share/applications/fedora-smolt.desktop \
	|| die 'dosed'

	dosym ${MYDIR}/sendProfile.py /usr/bin/smoltSendProfile \
	|| die "dosym sendProfile"
	dosym ${MYDIR}/deleteProfile.py /usr/bin/smoltDeleteProfile \
	|| die "dosym deleteProfile"
	dosym ${MYDIR}/smoltGui.py /usr/bin/smoltGui \
	|| die "dosym smoltGui"
	dosym /etc/smolt/config.py ${MYDIR}/config.py \
	|| die "dosym config.py"

	cd man
	doman smoltSendProfile.1 smoltDeleteProfile.1 smoltGui.1 || die "doman"

	cd ../..
	dodoc README doc/PrivacyPolicy || die "dodoc"
	newinitd "${FILESDIR}"/${PN}-init.d ${PN} || die "newinitd"

	exeinto /usr/share/doc/${PF}
	exeopts -m0744
	doexe "${FILESDIR}/smolt_monthly.sh" || die "doexe"
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"/usr/share/${PN}

	elog
	einfo "Call smoltSendProfile as root in order to initialize your profile."
	elog
	einfo "You can withdraw it from the server if you wish to with"
	einfo "   smoltDeleteProfile any time later on."
	elog

	if has_version "<virtual/python-2.5"; then
		einfo "If you want to view your profile on the web from within smoltGui,"
		einfo "you should have a link mozilla-firefox -> firefox in your path."
		elog
	fi
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}
}