# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/hedgewars/hedgewars-0.9.7.ebuild,v 1.1 2008/11/05 00:26:57 mr_bones_ Exp $

EAPI=1
inherit games cmake-utils

MY_P="${PN}-src-${PV}"
DESCRIPTION="Free Worms-like turn based strategy game"
HOMEPAGE="http://hedgewars.org/"
SRC_URI="http://hedgewars.org/download/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dedicated"

RDEPEND="|| (
		( x11-libs/qt-gui:4 x11-libs/qt-svg:4 )
		>=x11-libs/qt-4.4:4
	)
	media-libs/libsdl
	media-libs/sdl-ttf
	media-libs/sdl-mixer
	media-libs/sdl-image
	media-libs/sdl-net"
DEPEND="${RDEPEND}
	>=dev-lang/fpc-2.2
	dedicated? (
		dev-lang/ghc
		dev-haskell/stm
		dev-haskell/network
	)"

S="${WORKDIR}/${MY_P}"

src_compile() {
	local mycmakeargs
	GAMES_PREFIX="/usr"

	mycmakeargs="${mycmakeargs}
			-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}
			-DDATA_INSTALL_DIR=${GAMES_DATADIR}
			-DBIN_INSTALL_DIR=${GAMES_BINDIR}
			$(cmake-utils_use_with dedicated SERVER)
			"

	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install

	newicon QTfrontend/res/hh25x25.png ${PN}.png
	make_desktop_entry ${PN} Hedgewars
	dodoc ChangeLog.txt README
	doman man/${PN}.6
	prepgamesdirs
}