unicap-0.9.3.ebuild

unicap-0.9.3.ebuild (text/plain), 1.92 KB, created by Matt Whitlock on 2008-10-27 05:01:49 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="The uniform API for image acquisition devices"
HOMEPAGE="http://unicap-imaging.org/"
SRC_URI="http://unicap-imaging.org/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug ffmpeg gtk ieee1394 nls png theora threads v4l v4l2"

DEPEND="alsa? ( media-libs/alsa-lib )
	ffmpeg? ( media-video/ffmpeg )
	gtk? ( >=x11-libs/gtk+-2.0 )
	ieee1394? ( >=sys-libs/libraw1394-0.10.0 )
	theora? ( media-libs/libtheora )"
RDEPEND="${DEPEND}"

src_compile() {
	local myconf=""

	if use debug ; then
		myconf="${myconf} --enable-thing --enable-debug-unicap \
		--enable-debug-ucil --enable-debug-thing"
		use gtk && myconf="${myconf} --enable-debug-unicapgtk"
		use ieee1394 && myconf="${myconf} --enable-debug-dcam --enable-debug-vid21394"
		use v4l && myconf="${myconf} --enable-debug-v4l"
		use v4l2 && myconf="${myconf} --enable-debug-v4l2"
	fi

	# fix typo
	use ffmpeg && sed -i -e's:UCIL_FOURC(:UCIL_FOURCC(:' "${S}"/libucil/ucil_avc_avi.c

	# fix #includes for newer versions of ffmpeg
	use ffmpeg && [[ -d "${ROOT}"/usr/include/libavcodec ]] && sed -i \
		-e's:^#include <avcodec.h>$:#include <libavcodec/avcodec.h>:' \
		-e's:^#include <avutil.h>$:#include <libavutil/avutil.h>:' \
		"${S}"/libucil/{colorspace,ucil_avc_avi}.c

	econf ${myconf} \
		$(use_enable alsa ucil-alsa) \
		$(use_enable ffmpeg ucil-avcodec) \
		$(use_enable gtk unicapgtk) \
		$(use_enable ieee1394 dcam) \
		$(use_enable ieee1394 vid21394) \
		$(use_enable nls) \
		$(use_enable png ucil-png) \
		$(use_enable theora ucil-theora) \
		$(use_enable threads unicap-threads) \
		$(use_enable v4l) \
		$(use_enable v4l2) \
		--enable-ucil || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README README.troubleshooting
}