PKGBUILD from Archlinux

PKGBUILD (text/plain), 1.60 KB, created by Heiko Baums on 2008-10-13 18:08:18 UTC

# Contributor: Heiko Baums <[e-mail]>

pkgname=qdvdauthor
pkgver=1.5.0
pkgrel=2
pkgdesc="'Q' DVD-Author is a Qt-based DVD authoring suite"
url="http://qdvdauthor.sourceforge.net"
license=('GPL')
arch=('i686' 'x86_64')
depends=('dvdauthor' 'imagemagick' 'ffmpeg' 'mjpegtools' 'dvd-slideshow' 'xine-lib' 'mplayer' 'qt' 'qt3' 'netpbm' 'videotrans' 'toolame' 'lame' 'sox')
source=(http://dl.sourceforge.net/$pkgname/$pkgname-$pkgver-2.tar.gz)
md5sums=('1d1f29825fe0ae49faac8a0269c5c550')

build() {
  cd $srcdir/$pkgname-$pkgver

  # Set our C(XX)FLAGS
  for PRO in */*.pro */*/*.pro; do
    echo "QMAKE_CFLAGS_RELEASE = ${CFLAGS}" >> "${PRO}"
    echo "QMAKE_CXXFLAGS_RELEASE = ${CXXFLAGS}" >> "${PRO}"
  done

  # Build qrender
  cd $srcdir/$pkgname-$pkgver/qrender
  # Change a symlink to get access to avformat.h, could also patch $srcdir/$pkgname-$pkgver/qrender/engine/ffmpeg_enc.cpp
  rm ffmpeg
  ln -s /usr/include/libavformat ffmpeg
  export STATIC_FFMPEG=1
  # Have qrender look for ffmpeg in /usr instead of /usr/local
  sed -i "s:\/local::g" qrender.pro
  qmake || return 1
  make || return 1
  make INSTALL_ROOT=$pkgdir install || return 1

  # Build qdvdauthor
  cd $srcdir/$pkgname-$pkgver
  export QTDIR=/opt/qt
  export QMAKESPEC=/opt/qt/mkspecs/linux-g++

  ./configure --build-qplayer --build-qslideshow --with-xine-support --with-mplayer-support --qt-dir=$QTDIR || return 1
  make INSTALL_ROOT=$pkgdir install || return 1

  cd $srcdir/$pkgname-$pkgver
  install -D -m644 $pkgname.desktop $pkgdir/usr/share/applications/$pkgname.desktop
  install -D -m644 $pkgname.png $pkgdir/usr/share/pixmaps/$pkgname.png
}