licq-1.3.6

licq-1.3.6.ebuild (text/plain), 3.13 KB, created by Tomáš Chvátal (RETIRED) on 2008-10-12 10:28:47 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/licq/licq-1.3.5-r1.ebuild,v 1.6 2008/07/05 16:48:39 armin76 Exp $

EAPI="1"
WANT_AUTOMAKE=1.9

inherit autotools eutils kde-functions multilib

DESCRIPTION="ICQ Client with v8 support"
HOMEPAGE="http://www.licq.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~x86"
IUSE="crypt debug kde msn ncurses nls qt3 qt4 socks5 ssl osd"

# we use kde as KDE4
RDEPEND="kde? ( 
		qt4? ( kde-base/kdelibs:4.1 )
		qt3? ( kde-base/kdelibs:3.5 )
	)
	ssl? ( dev-libs/openssl )
	qt3? ( x11-libs/qt:3 )
	qt4? ( x11-libs/qt-gui:4 )
	nls? ( sys-devel/gettext )
	ncurses? ( sys-libs/ncurses =dev-libs/cdk-5* )
	crypt? ( app-crypt/gpgme:1 )
	osd? ( x11-libs/xosd )"
DEPEND="${RDEPEND}
	dev-libs/boost
	qt4? ( >=dev-util/cmake-2.6.2 )"

_generate_plugins_directories() {
	PLUGINS="auto-reply email rms"
	use msn && PLUGINS="${PLUGINS} msn"
	use ncurses && PLUGINS="${PLUGINS} console"
	use osd &&  PLUGINS="${PLUGINS} osd"
	# QT4 is something extra. Uses cmake.
	use qt4 && PLUGINS_CMAKE="${PLUGINS_CMAKE} qt4-gui"
	use qt3 && PLUGINS="${PLUGINS} qt-gui"
	elog "I will generate these plugins/frontends for licq:"
	elog "${PLUGINS} ${PLUGINS_CMAKE}"
}

pkg_setup() {
	_generate_plugins_directories
}

src_compile() {
	local myconf myconf2 plugin
	# global config setup for automake
	myconf="$(use_enable crypt gpgme)
		$(use_enable ssl openssl)
		$(use_enable socks5)
		$(use_enable debug)
		$(use_enable nls)"

	einfo "Compiling Licq core."
	econf ${myconf} || die "econf failed"
	emake || die "emake failed"

	for plugin in ${PLUGINS}; do
		cd "${S}"/plugins/"${plugin}"
		einfo "Compiling Licq: \"${plugin}\"."
		if use qt3; then
			set-qtdir 3
			set-kdedir 3
			use kde && myconf2="${myconf} --with-kde"
			myconf2="${myconf2} --with-qt-libraries=${QTDIR}/$(get_libdir)"
		fi
		econf ${myconf} ${myconf2} || die "econf failed"
		emake || die "emake failed"
	done
	# we like qt4 it uses cmake
	if use qt4; then
		cd "${S}"/plugins/qt4-gui
		einfo "Compiling Licq: \"qt4-gui\"."
		# Possible error because of one tiny issue we introduce in kde
		# it is called kdeprefix and in that case you cant be sure where
		# find kde stuff. This is working only for -kdeprefix so someone
		# fix.
		myconf2="-DCMAKE_INSTALL_PREFIX=/usr"
		use kde && myconf2="${myconf2} -DWITH_KDE=1"
		cmake . ${myconf2} || die "cmake failed"
		emake || die "emake failed"
	fi
}

src_install() {
	# install core
	einfo "Installing Licq core."
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc ChangeLog INSTALL README* doc/*
	# Install the plug-ins
	for plugin in ${PLUGINS}; do
		cd "${S}"/plugins/"${plugin}"
		einfo "Installing Licq: \"${plugin}\"."
		emake DESTDIR="${D}" install || die "emake install failed"
		dodoc README* *.conf
	done
	if use qt4; then
		cd "${S}"/plugins/qt4-gui
		einfo "Installing Licq: \"qt4-gui\"."
		emake DESTDIR="${D}" install || die
		docinto plugins/qt4-gui
		dodoc doc/README*
	fi

	exeinto /usr/share/${PN}/upgrade
	doexe "${S}"/upgrade/*

	# fixes bug #22136 and #149464
	#rm -fR "${D}"/var
}