Working ebuild

conspire-0.20.ebuild (text/plain), 1.28 KB, created by Kent Fredric (IRC: kent\n) (RETIRED) on 2008-10-12 02:43:30 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/conspire/conspire-0.20.ebuild,v 1.1 2008/07/20 14:02:05 chainsaw Exp $

MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="A high quality IRC client which uses a multitude of interfaces"
HOMEPAGE="http://www.nenolod.net/conspire/"
SRC_URI="http://distfiles.atheme.org/${MY_P}.tbz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
IUSE="python gnutls ipv6 nls mmx socks5 dbus"
DEPEND="nls? ( dev-util/intltool )"
RDEPEND=">=dev-libs/libmowgli-0.6.0
	>=x11-libs/gtk+-2.10
	>=dev-libs/glib-2.14
	x11-libs/libnotify
	x11-libs/libsexy
	dbus? ( >=dev-libs/dbus-glib-0.60 )
	python? ( >=dev-lang/python-2.2 )"

src_compile() {
	econf \
		$(use_enable socks5 socks) \
		$(use_enable ipv6) \
		$(use_enable gnutls) \
		$(use_enable python) \
		$(use_enable mmx) \
		$(use_enable nls) \
		$(use_enable dbus) \
		--enable-spell=libsexy \
		--enable-regex \
		|| die
	emake || die "emake failed"
}

src_unpack() {
	unpack ${A}
	einfo "Applying GtkType Fix" 
	sed -i 's/GtkType/GType/' ${WORKDIR}/conspire-${PV}/src/fe-gtk/xtext.h \
		|| die "Fix Didn't work"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc NEWS TODO
}