libformula

libformula-0.1.18.2.ebuild (text/plain), 966 bytes, created by Hanno Zysik (geki) on 2008-10-02 11:16:13 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

DESCRIPTION="JFree LibFormula"
HOMEPAGE="http://www.jfree.org/jfreereport/index.php"
SRC_URI="mirror://sourceforge/jfreechart/${P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug"

CDEPEND="dev-java/jcommon"
RDEPEND="${CDEPEND}
	>=virtual/jre-1.4"
DEPEND="${CDEPEND}
	>=virtual/jdk-1.4"

src_unpack() {
	unpack ${A}
	cd "${S}"
	rm -v *.jar lib/*.jar || die

	cd "${S}/lib"
	 java-pkg_jar-from jcommon-1.0
}

src_compile() {
	local antflags="-Djcommon-jar-file=jcommon.jar"
	use !debug && antflags="${antflags} -Dbuild.debug=false -Dbuild.optimize=true"
	eant compile $(use_doc) ${antflags}
}

src_install() {
	java-pkg_newjar ${P}.jar ${PN}.jar
	dodoc README.txt || die
	use doc && java-pkg_dojavadoc javadoc
	use source && java-pkg_dosrc source/org
}