# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$

inherit eutils games

DESCRIPTION="High quality custom content addon for Neverwinter Nights"
HOMEPAGE="http://nwvault.ign.com/cep/"
SRC_URI="http://vnfiles.ign.com/nwvault.ign.com/fms/files/hakpaks/7478/CEP_2_Full_c.7z
	http://vnfiles.ign.com/nwvault.ign.com/fms/files/hakpaks/7478/CEP21_Start_Mod.7z"

LICENSE="as-is"
SLOT="2"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""

DEPEND="app-arch/p7zip"
RDEPEND=">=games-rpg/nwn-1.69"

S=${WORKDIR}

dir=${GAMES_PREFIX_OPT}/nwn

pkg_setup() {
	games_pkg_setup
	if ! built_with_use games-rpg/nwn-data sou || ! built_with_use games-rpg/nwn-data hou
	then
		eerror "${P} requires NWN v1.69, Shadows of Undrentide, and Hordes of"
		eerror "the Underdark. Please make sure you have all three before using"
		eerror "this patch."
		die "Requirements not met"
	fi
}

src_install() {
	local i
	for i in hak tlk erf
	do
		insinto "${dir}"/${i}
		doins *.${i} || die "${i} failed"
	done
	insinto "${dir}"/modules
	doins *.mod || die "mod failed"
	insinto "${dir}"/cep
	doins *.pdf || die "pdf failed"
	doins *.txt || die "txt failed"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "The NWN Community Expansion Pack (CEP) v2.1 is now installed."
	elog "Proceed with the following step in order to get it working:"
	elog "Run ${dir}/fixinstall as root"
}