# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="C++ class library normalising numerous telephony protocols"
#DESCRIPTION="C++ class library for applications that wish to use the SIP and
#H.323 protocols for multi-media communications over packet based networks"
HOMEPAGE="http://www.ekiga.org"
SRC_URI="http://www.ekiga.org/admin/downloads/latest/sources/sources/${P}.tar.gz"

LICENSE="MPL-1.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug doc java zrtp"

RDEPEND="~dev-libs/ptlib-2.4.1
	>=media-video/ffmpeg-0.4.7
	media-libs/speex
	java? ( virtual/jdk )
	zrtp? ( net-libs/libzrtpcpp )"

pkg_setup() {
	if use debug && ! built_with_use dev-libs/ptlib debug; then
		eerror "You need to build dev-libs/ptlib with USE=debug enabled."
		die "dev-libs/ptlib has to be built with USE=debug"
	fi

	if ! use debug && built_with_use dev-libs/ptlib debug; then
		eerror "You need to build dev-libs/ptlib without USE=debug."
		die "dev-libs/ptlib has not to be built with USE=debug"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${P}-lpcini.patch
}

src_compile() {
	local makeopts

	econf \
		--enable-plugins \
		--disable-localspeex \
		$(use_enable debug) \
		$(use_enable java) \
		$(use_enable zrtp) \
		|| die "econf failed"

	if use debug; then
		makeopts="debug"
	else
		makeopts="opt"
	fi

	emake ${makeopts} || die "emake failed"
}

src_install() {
	emake PREFIX=/usr DESTDIR="${D}" install || die "emake install failed"

	# installing documentation
	if use doc; then
		dohtml -r html/* docs/* || die "documentation installation failed"
	fi
}