qutecom-2.2_rc1.ebuild

qutecom-2.2_rc1.ebuild (text/plain), 1.56 KB, created by Chí-Thanh Christopher Nguyễn on 2008-09-19 21:39:44 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit cmake-utils eutils

MY_P=${P/_rc/-RC}

DESCRIPTION="An open source softphone"
HOMEPAGE="http://www.qutecom.com/"
SRC_URI="http://www.qutecom.com/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug oss portaudio xv"

RDEPEND=">=dev-libs/boost-1.34
	dev-libs/glib
	dev-libs/openssl
	alsa? ( media-libs/alsa-lib )
	media-libs/libsamplerate
	media-libs/libsndfile
	portaudio? ( >=media-libs/portaudio-19_pre )
	media-libs/speex
	<media-video/ffmpeg-20080206
	net-libs/gnutls
	>=net-libs/libosip-3
	net-misc/curl
	|| ( x11-libs/libX11 virtual/x11 )
	|| ( ( x11-libs/qt-gui:4 x11-libs/qt-svg:4 ) =x11-libs/qt-4.3* )
	xv? ( x11-libs/libXv )"

DEPEND="${RDEPEND}
	!dev-util/mercurial"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-boost-1.35.patch
	epatch "${FILESDIR}"/${PN}-types.h.patch
	epatch "${FILESDIR}"/${PN}-cstdlib-include.patch
	epatch "${FILESDIR}"/${PN}-gcc-4.3-switch-enum.patch
}

src_compile() {
	EXTRA_ECONF=" \
		$(cmake_use_enable portaudio PORTAUDIO_SUPPORT) \
		$(cmake_use_enable alsa PHAPI_AUDIO_ALSA_SUPPORT) \
		$(cmake_use_enable oss PHAPI_AUDIO_OSS_SUPPORT) \
		$(cmake_use_enable xv WENGOPHONE_XV_SUPPORT) "

	cmake-utils_src_configureout
	cmake-utils_src_make
}

src_install() {
	cmake-utils_src_install
	domenu "${S}"/wengophone/res/wengophone.desktop || ewarn "domenu failed"
	doicon "${S}"/wengophone/res/wengophone_64x64.png || ewarn "doicon failed"
}