##########################libwww Support####################

dnl

dnl libwww are enabled by default

dnl

AC_ARG_ENABLE([system-libwww],

	AC_HELP_STRING([--enable-system-libwww],[try the libwww system library]),

	[case "${enableval}" in

	  yes) with_system_libwww="yes";;

	  no)  with_system_libwww="no" ;;

	  *) AC_MSG_ERROR(bad value ${enableval} for --enable-system-libwww) ;;

	esac],

	[with_system_libwww="no"])

#If libwww is needed and we are asked

#to use the system library, check if is present

if test "$with_libwww" = "yes" -a "$with_system_libwww" = "yes" ; then

    # check to see if we have a libwww library

    AC_PATH_PROG([LIBWWW_CONFIG],[libwww-config])

    if test "$LIBWWW_CONFIG" = "" ; then

      AC_MSG_WARN(Not using system-provided libwww library)

      with_system_libwww="no"

    fi

fi

#if we use the builtin library,

#check it is present

if test "$with_libwww" = "yes" -a "$with_system_libwww" != "yes" \

	-a ! -d "$srcdir/../libwww" ; then

	AC_MSG_WARN(libwww source dir not found !!)

	AC_MSG_WARN(Disabling libwww build !)

	with_libwww="no"

fi

#At this point, we know everything about libwww,

#so either set the variables we will need later,

#or disable Annotations

if test "$with_libwww" = "yes" ; then

	if test "$with_system_libwww" != "yes" ; then

		www_frag=$srcdir/amaya/Makefile.libwww

		AC_SUBST_FILE(www_frag)

	else

		AMAYA_LIBWWW_INCLUDES=`$LIBWWW_CONFIG --cflags`

		AMAYA_LIBWWW_LIBS=`$LIBWWW_CONFIG --libs`

       fi

else

	with_libwww="no"

fi

#AC_SUBST(BUILDLIBWWW)

AC_SUBST(AMAYA_LIBWWW_LIBS)

AC_SUBST(AMAYA_LIBWWW_INCLUDES)

###################End of libwww Support####################