# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1

inherit toolchain-funcs flag-o-matic fdo-mime

MY_P=VirtualBox-${PV}-OSE
DESCRIPTION="Softwarefamily of powerful x86 virtualization"
HOMEPAGE="http://www.virtualbox.org/"
SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+additions alsa hardening headless pulseaudio sdk qt3 +qt4 python"

RDEPEND="!app-emulation/virtualbox-bin
	~app-emulation/virtualbox-modules-${PV}
	!headless? (
		qt3? ( x11-libs/qt:3 )
		qt4? ( x11-libs/qt:4 )
		>=media-libs/libsdl-1.2.7
		>=media-libs/sdl-ttf-2.0.6
		x11-libs/libXcursor
		x11-libs/libX11
		x11-libs/libXext )
	python? ( >=dev-lang/python-2.3 )
	>=dev-libs/libxslt-1.1.17
	sys-libs/glibc
	>=dev-libs/libxml2-2.6.26
	dev-libs/libIDL
	>=sys-libs/zlib-1.2.1
	alsa? ( >=media-libs/alsa-lib-1.0.6 )
	pulseaudio? ( media-sound/pulseaudio )
	net-misc/bridge-utils
	additions? ( ~app-emulation/virtualbox-ose-additions-${PV} )"
DEPEND="${RDEPEND}
	sys-devel/dev86
	sys-devel/bin86
	sys-power/iasl
	>=media-libs/libpng-1.2.5
	dev-util/kbuild
	>=dev-lang/yasm-0.6.2
	<sys-devel/gcc-4.3"

S=${WORKDIR}/${MY_P/-OSE/}

pkg_setup() {
	# known problems with gcc 4.3 and the recompiler
	# http://www.virtualbox.org/ticket/936
	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "43" ]]; then
			eerror "there are known problems with gcc 4.3 and the virtualbox"
			eerror "recompiler stuff. Please use at least a version of gcc < 4.3"
			die "gcc 4.3 cannot build the virtualbox recompiler"
	fi

	if ! use headless; then
			# The VBoxSDL frontend needs media-libs/libsdl compiled
			# with USE flag X enabled (bug #177335)
			if ! built_with_use media-libs/libsdl X; then
				eerror "media-libs/libsdl was compiled without the \"X\" USE flag enabled."
				eerror "Please re-emerge media-libs/libsdl with USE=\"X\"."
				die "media-libs/libsdl should be compiled with the \"X\" USE flag."
			fi
	else
			if use qt3 || use qt4; then
					einfo ""
					einfo "You selected USE=\"(qt3 | qt4) headless\", defaulting to"
					einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
					einfo ""
			fi
	fi

	if use hardening; then
			ewarn "Enabling hardening will make VirtualBox only work when run"
			ewarn "as root"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Remove shipped binaries (kBuild,yasm), see bug #232775
	rm -rf kBuild/bin tools

	# Don't build things unused or splitted into separate ebuilds (eg: additions)
	epatch "${FILESDIR}/${P}-remove-unused.patch"
}

src_compile() {

	local myconf
	# Don't build vboxdrv kernel module
	myconf="--disable-kmods"

        use hardening || myconf="${myconf} --disable-hardening"
	use pulseaudio || myconf="${myconf} --disable-pulse"
	use alsa || myconf="${myconf} --disable-alsa"
	use headless && myconf="${myconf} --build-headless"
	use python || myconf="${myconf} --disable-python"
	use qt3 || myconf="${myconf} --disable-qt3"
	use qt4 || myconf="${myconf} --disable-qt4"

	./configure --with-gcc="$(tc-getCC)" --with-g++="$(tc-getCXX)" \
	${myconf} || die "configure failed"
	source ./env.sh
	export KBUILD_PATH="${S}/kBuild"

	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
	# and strip all flags
	strip-flags

	MAKE="kmk" emake TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
		TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
		TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
		TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
		TOOL_YASM_AS=yasm \
		all || die "kmk failed"
}

src_install() {
	cd "${S}"/out/linux.${ARCH}/release/bin

	# create virtualbox configurations files
	insinto /etc/vbox
	newins "${FILESDIR}/${PN}-config" vbox.cfg
	newins "${FILESDIR}/${PN}-interfaces" interfaces

	insinto /opt/VirtualBox
	if use sdk; then
		doins -r sdk
		fowners root:vboxusers /opt/VirtualBox/sdk/bin/xpidl
		fperms 0750 /opt/VirtualBox/sdk/bin/xpidl
	fi

	rm -rf sdk src tst* testcase xpidl SUPInstall SUPUninstall VBox.png \
	VBoxBFE vditool VBoxSysInfo.sh vboxkeyboard.tar.gz

	doins -r *

	if ! use headless; then
			for each in VBox{Manage,SDL,SVC,XPCOMIPCD,Tunctl,Headless} ; do
				fowners root:vboxusers /opt/VirtualBox/${each}
				fperms 0750 /opt/VirtualBox/${each}
			done

			if use qt3; then
				fowners root:vboxusers /opt/VirtualBox/VirtualBox3
				fperms 0750 /opt/VirtualBox/VirtualBox3

				dosym /opt/VirtualBox/VBox.sh /usr/bin/VirtualBox3
			fi
			if use qt4; then
				fowners root:vboxusers /opt/VirtualBox/VirtualBox
				fperms 0750 /opt/VirtualBox/VirtualBox

				dosym /opt/VirtualBox/VBox.sh /usr/bin/VirtualBox
			fi

			dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxSDL

			newicon	"${S}"/src/VBox/Frontends/VirtualBox/images/OSE/VirtualBox_32px.png ${PN}.png
			domenu "${FILESDIR}"/${PN}.desktop
	else
			for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl,Headless} ; do
				fowners root:vboxusers /opt/VirtualBox/${each}
				fperms 0750 /opt/VirtualBox/${each}
			done
	fi

	exeinto /opt/VirtualBox
	newexe "${FILESDIR}/${PN}-wrapper" "VBox.sh" || die
	fowners root:vboxusers /opt/VirtualBox/VBox.sh
	fperms 0750 /opt/VirtualBox/VBox.sh
	newexe "${S}"/src/VBox/Installer/linux/VBoxAddIF.sh "VBoxAddIF.sh" || die
	fowners root:vboxusers /opt/VirtualBox/VBoxAddIF.sh
	fperms 0750 /opt/VirtualBox/VBoxAddIF.sh

	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxManage
	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxVRDP
	dosym /opt/VirtualBox/VBox.sh /usr/bin/VBoxHeadless
	dosym /opt/VirtualBox/VBoxTunctl /usr/bin/VBoxTunctl
	dosym /opt/VirtualBox/VBoxAddIF.sh /usr/bin/VBoxAddIF
	dosym /opt/VirtualBox/VBoxAddIF.sh /usr/bin/VBoxDeleteIF
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog ""
	if ! use headless; then
		if use qt4; then
			elog "To launch VirtualBox just type: \"VirtualBox\""
		elif use qt3; then
			elog "To launch VirtualBox just type: \"VirtualBox3\""
		fi
	fi
	elog "You must be in the vboxusers group to use VirtualBox."
	elog ""
	elog "The last user manual is available for download at:"
	elog "http://www.virtualbox.org/download/UserManual.pdf"
	elog ""
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	elog ""
	if ! use headless; then
		if use qt4; then
			elog "To launch VirtualBox with qt4 interface just"
			elog "type: \"VirtualBox\""
		fi
		if use qt3; then
			elog "To launch VirtualBox with qt3 interface just"
			elog "type: \"VirtualBox3\""
		fi
	fi
	elog "To launch VirtualBox without graphical interface"
	elog "just type \"VBoxHeadless\""
	elog ""
	elog "You must be in the vboxusers group to use VirtualBox."
	elog ""
	elog "The last user manual is available for download at:"
	elog "http://www.virtualbox.org/download/UserManual.pdf"
	elog ""
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}