ibus-table-0.1.1.20080901.ebuild

ibus-table-0.1.1.20080901.ebuild (text/plain), 1.42 KB, created by Hong Hao on 2008-09-06 07:51:44 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"
inherit eutils

DESCRIPTION="The Table Engine for IBus Framework"
HOMEPAGE="http://ibus.googlecode.com"
SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="additional cangjie5 erbi-qs +extra-phrases nls wubi zhengma"

DEPEND=">=dev-lang/python-2.5
	nls? ( sys-devel/gettext )"
RDEPEND="app-i18n/ibus
	>=dev-lang/python-2.5"

pkg_setup() {
	if ! built_with_use '>=dev-lang/python-2.5' sqlite; then
		ewarn "You need build dev-lang/python with \"sqlite\" USE flag!"
		die "Please rebuild dev-lang/python with sqlite USE flag!"
	fi
}

src_compile() {
	econf $(use_enable additional) \
		$(use_enable cangjie5) \
		$(use_enable erbi-qs) \
		$(use_enable extra-phrases) \
		$(use_enable nls) \
		$(use_enable wubi wubi86) \
		$(use_enable wubi wubi98) \
		$(use_enable zhengma) \
		--disable-option-checking \
		--disable-rpath
	emake || die "emake failed"
}

src_install() {
	emake install DESTDIR="${D}" || die "Install failed"
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	ewarn "This package is very experimental, please report your bugs to"
	ewarn "http://ibus.googlecode.com/issues/list"
	elog
	elog "You should set USE flag properly before installing this package."
	elog "Don't forget to run ibus-setup and enable the IM Engines you want to use!"
	elog
}