# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/netscape-flash/netscape-flash-10_beta20080702.ebuild,v 1.1 2008/07/03 13:42:46 lack Exp $

inherit nsplugins versionator

MV=$(get_major_version)

# Excellent, Adobe uses that unsortable though surprisingly popular date
# convention "MMDDYY", so build that out of a proper "YYYYMMDD" beta version
# component:
RC=$(get_version_component_range 2)
RC=${RC#rc}
BV=${RC:4:2}${RC:6:2}${RC:2:2}

DESCRIPTION="Adobe Flash Player"
SRC_URI="http://download.macromedia.com/pub/labs/flashplayer${MV}/flashplayer${MV}_install_linux_${BV}.tar.gz"
HOMEPAGE="http://www.adobe.com/"
IUSE=""
SLOT="0"

KEYWORDS="-* ~amd64 ~x86"
LICENSE="AdobeFlash-9.0.31.0"
RESTRICT="strip mirror"

S="${WORKDIR}/install_flash_player_${MV}_linux"

INSTALL_DIR="/opt/netscape/plugins"
ADOBE_LIBS="/opt/Adobe/Reader8/Reader/intellinux/lib"

DEPEND="amd64? ( app-emulation/emul-linux-x86-baselibs
			app-emulation/emul-linux-x86-gtklibs
			app-emulation/emul-linux-x86-soundlibs
			 app-emulation/emul-linux-x86-xlibs )
	x86? ( x11-libs/libXext
		x11-libs/libX11
		x11-libs/libXt
		=x11-libs/gtk+-2*
		media-libs/freetype
		media-libs/fontconfig )
	media-fonts/corefonts
	dev-libs/nss
	>=sys-libs/glibc-2.4
	app-text/acroread"

pkg_setup() {
	# This is a binary x86 package => ABI=x86
	# Please keep this in future versions
	# Danny van Dyk <kugelfang@gentoo.org> 2005/03/26
	has_multilib_profile && ABI="x86"
}

src_install() {
	exeinto ${INSTALL_DIR}
	doexe libflashplayer.so
	inst_plugin ${INSTALL_DIR}/libflashplayer.so

	dosym ${ADOBE_LIBS}/libcurl.so.3 ${INSTALL_DIR}
	dosym ${ADOBE_LIBS}/libssl.so.0.9.7 ${INSTALL_DIR}
	dosym ${ADOBE_LIBS}/libcrypto.so.0.9.7 ${INSTALL_DIR}

	inst_plugin ${INSTALL_DIR}/libcurl.so.3
	inst_plugin ${INSTALL_DIR}/libssl.so.0.9.7
	inst_plugin ${INSTALL_DIR}/libcrypto.so.0.9.7
}