ypsilon-0.9.6.ebuild

ypsilon-0.9.6.ebuild (text/plain), 1.29 KB, created by Dmitry Dzhus on 2008-08-11 18:58:48 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="R6RS-compliant Scheme implementation for real-time applications."
HOMEPAGE="http://code.google.com/p/ypsilon/"
SRC_URI="http://ypsilon.googlecode.com/files/${P}.tar.gz"
LICENSE="BSD"

SLOT="0"
KEYWORDS="~x86"
IUSE="examples threads"

DEPEND=""
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${A}

	cd "${S}"
	# LDFLAGS must not be used to specify libs to link against
	sed -i -e "s:\$(LDFLAGS):\$(LDFLAGS) -ldl -lpthread:" Makefile

	# Fix executable stack
	epatch "${FILESDIR}/${P}-fix-stack.patch"
	mv src/ffi_stub_linux.s src/ffi_stub_linux.S

	# Avoid shortcut implicit rule to make .o directly from .S
	echo "ffi_stub_linux.s: ffi_stub_linux.S" >> Makefile
}

src_compile() {
	# Upstream Makefile specifically sets these flags
	append-flags "-fno-align-labels -fno-align-loops -fno-align-jumps"

	use threads && append-flags "-pthread"

	emake PREFIX="/usr" CXX="$(tc-getCXX)" \
		LDFLAGS="${LDFLAGS}" CXXFLAGS="${CXXFLAGS}" || die "emake failed"
}

src_install() {
	emake PREFIX="${D}/usr" install || die "Install failed"
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins example/* || die "Failed to install examples"
	fi
}