games-arcade/tecnoballz/tecnoballz-0.92.ebuild

tecnoballz-0.92.ebuild (text/plain), 1.71 KB, created by Andreas Thillosen on 2008-07-22 01:07:11 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils games

MY_PV="0.92"
REV="2.1"
MY_P="${PN}_${MY_PV}"
MY_P_DASH="${MY_P/_/-}"
DEBIAN="mirror://debian/pool/main/t/${PN}"

DESCRIPTION="Brick Breaker with 50 levels of game and 11 special levels"
HOMEPAGE="http://linux.tlk.fr/games/TecnoballZ/
	http://packages.debian.org/unstable/games/tecnoballz"
SRC_URI="${DEBIAN}/${MY_P}.orig.tar.gz
	${DEBIAN}/${MY_P}-${REV}.diff.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND="virtual/libc
	media-libs/libmikmod
	media-libs/libogg
	>=media-libs/libsdl-1.2
	media-libs/libvorbis
	media-libs/sdl-mixer
	media-libs/smpeg
	x11-libs/libXext
	x11-libs/libXxf86dga
	x11-libs/libXxf86vm"

S=${WORKDIR}/${MY_P_DASH}

pkg_setup() {
	games_pkg_setup

	if ! built_with_use --missing true "media-libs/sdl-mixer" mikmod ; then
		die "Please emerge sdl-mixer with USE=mikmod"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}" || die

	epatch ./../"${MY_P}-${REV}.diff"

	find -name '.xvpics' -print0 | xargs -0 rm -rf
}

src_compile() {
	egamesconf \
		--bindir="${GAMES_BINDIR}" \
		--datadir="${GAMES_DATADIR}" \
		--localstatedir="${GAMES_STATEDIR}" \
		|| die "egamesconf"

	emake || die "emake"
}

src_install() {
	local dir=${GAMES_DATADIR}/${PN}

	# Cleanup
	find src/TecnoballZ -name Makefile\* -delete

	dogamesbin src/${PN} || die "dogamesbin"

	insinto "${dir}"
	doins -r src/TecnoballZ/* || die "doins TecnoballZ"

	doicon "${PN}.xpm" || die "doicon"
	make_desktop_entry ${PN} "TecnoballZ" ${PN}.xpm

	doman man/${PN}.6 || die "doman"
	dodoc AUTHORS CHANGES README

	insinto "${GAMES_STATEDIR}/${PN}"
	insopts -m 660
	doins ${PN}.hi || die

	prepgamesdirs
}