# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1

EANT_ANT_TASKS="jakarta-regexp-1.4 batik-1.6 xalan xsdlib relaxng-datatype"
EANT_GENTOO_CLASSPATH="swing-layout-1,stax-ex,xmlstreambuffer,sjsxp,concurrent-util,jsr173,jsr181,jsr250,saaj-api,fastinfoset,itext,jdom-1.0,junit,colt"
JAVA_ANT_REWRITE_CLASSPATH="true"

inherit versionator java-pkg-2 java-ant-2 eutils

MY_PV=$(replace_all_version_separators '_')

DESCRIPTION="A visualization platform for molecular interaction networks"
HOMEPAGE="http://www.cytoscape.org/"
SRC_URI="http://chianti.ucsd.edu/Cyto-${MY_PV}/cytoscapeSource-v${PV}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE=""
KEYWORDS="~amd64 ~x86"

COMMON_DEPS="dev-java/swing-layout:1
	dev-java/stax-ex
	dev-java/xmlstreambuffer
	dev-java/sjsxp
	dev-java/concurrent-util
	dev-java/jsr173
	dev-java/jsr181
	dev-java/jsr250
	java-virtuals/saaj-api
	dev-java/fastinfoset
	dev-java/itext
	dev-java/jdom:1.0
	dev-java/junit
	dev-java/colt"
DEPEND=">=virtual/jdk-1.6
	dev-java/jakarta-regexp:1.4
	dev-java/batik:1.6
	dev-java/xalan
	dev-java/xsdlib
	dev-java/relaxng-datatype
	${COMMON_DEPS}"
RDEPEND=">=virtual/jre-1.6
	${COMMON_DEPS}"

#	app-misc/openjnlp
#	dev-java/l2fprod-common - bug 216027

S="${WORKDIR}"

src_unpack() {
	unpack ${A}
#	java-ant_remove-taskdefs

	einfo "Removing bundled jars..."
	find -name 'batik*.jar' -print -delete
	find -name 'jakarta*.jar' -print -delete
	find -name 'xalan*.jar' -print -delete
	find -name 'xsdlib*.jar' -print -delete
	find -name 'relaxngDatatype.jar' -print -delete
	find -name 'swing-layout.jar' -print -delete
	find -name 'stax-ex.jar' -print -delete
	find -name 'saaj.jar' -print -delete
	find -name 'streambuffer.jar' -print -delete
	find -name 'sjsxp.jar' -print -delete
	find -name 'concurrent.jar' -print -delete
	find -name 'jsr*.jar' -print -delete
	find -name 'FastInfoset.jar' -print -delete
	find -name 'jdom*.jar' -print -delete
	find -name 'itext*.jar' -print -delete
	find -name 'colt.jar' -print -delete
	find -name 'junit.jar' -print -delete
#	find -name 'jnlp.jar' -print -delete
#	find -name 'jaxb*.jar' -print -delete
#	find -name 'l2fprod-common*.jar' -print -delete
	# Skip the jalopy ant build target (produces access violations)
	perl -i -ne 'print unless /taskdef.*name="jalopy"/../<\/target>/' build.xml || die
}

src_install() {
	java-pkg_dojar cytoscape.jar
	java-pkg_dojar lib/*.jar
	java-pkg_jarinto /usr/share/${PN}/plugins
	java-pkg_dojar plugins/core/*.jar

	# replacement for resources/bin/cytoscape.sh
	java-pkg_dolauncher cytoscape.sh --main cytoscape.CyMain \
		--java_args '-Dswing.aatext=true -Xss5M -Xmx512M' \
		--pkg_args '-p '/usr/share/${PN}/plugins' \"$@\"'
	insinto /usr/share/pixmaps
	newins images/icon100.png cytoscape.png
	make_desktop_entry cytoscape.sh Cytoscape /usr/share/pixmaps/cytoscape.png

	dodoc docs/pdf/manual.pdf
}