ebuild with split qt4 dependencies

mumble-1.1.4.ebuild (text/plain), 4.29 KB, created by Lorenz Quack on 2008-06-30 16:56:18 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit eutils toolchain-funcs qt4

DESCRIPTION="Voice chat software for gaming written in Qt4"
HOMEPAGE="http://mumble.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa dbus debug oss portaudio pulseaudio texttospeech"

RDEPEND=">=media-libs/speex-1.2_beta3_p2
	dev-libs/boost
	x11-libs/libXevie
	|| ( ( x11-libs/qt-core:4
		   x11-libs/qt-gui:4
		   x11-libs/qt-opengl:4
		   x11-libs/qt-sql:4
		   dbus? ( x11-libs/qt-dbus:4 ) )
		 ( =x11-libs/qt-4.3*:4 ) )
	alsa? ( media-libs/alsa-lib )
	dbus? ( sys-apps/dbus )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	texttospeech? ( app-accessibility/speech-dispatcher )"

DEPEND="${DEPEND}
	>=sys-devel/gcc-3.4"

pkg_setup() {
	echo
	local fail="no"
	if has_version "x11-libs/qt-core:4"; then
		# >=qt-4.4 checks
		if ! built_with_use x11-libs/qt-core ssl; then
			ewarn "You need to build qt-core with the ssl use-flag to enable it for ${PN}."
			fail="yes"
		fi
		if ! built_with_use x11-libs/qt-sql sqlite; then
			ewarn "You need to build qt-sql with the sqlite use-flags to enable it for ${PN}."
			fail="yes"
		fi
		if use dbus && ! built_with_use x11-libs/qt-gui dbus; then
			ewarn "You need to build qt-gui with the dbus use-flag to enable it for ${PN}."
			fail="yes"
		fi

		if use debug; then
			if ! built_with_use x11-libs/qt-core debug; then
				ewarn "qt-core has not been built with debug use-flag enabled."
				ewarn "This might compromise the debugging of ${PN}."
			fi
			if ! built_with_use x11-libs/qt-opengl debug; then
				ewarn "qt-opengl has not been built with debug use-flag enabled."
				ewarn "This might compromise the debugging of ${PN}."
			fi
			if ! built_with_use x11-libs/qt-sql debug; then
				ewarn "qt-sql has not been built with debug use-flag enabled."
				ewarn "This might compromise the debugging of ${PN}."
			fi
			if use dbus && ! built_with_use x11-libs/qt-dbus debug; then
				ewarn "qt-dbus has not been built with debug use-flag enabled."
				ewarn "This might compromise the debugging of ${PN}."
			fi
		fi
	else
		# <qt-4.4 checks
		if ! built_with_use =x11-libs/qt-4* opengl ssl sqlite3; then
			ewarn "You need to build Qt4 with the opengl, ssl and sqlite3 use-flags."
			fail="yes"
		fi
		if use dbus && ! built_with_use =x11-libs/qt-4* dbus; then
			ewarn "You need to build Qt4 with the dbus use-flag."
			fail="yes"
		fi
		if use debug && ! built_with_use =x11-libs/qt-4* debug; then
			ewarn "Qt4 has not been built with debug use-flag enabled."
			ewarn "This might compromise the debugging of ${PN}."
		fi
	fi

	if [[ -z "${fail}" || ${fail} == "yes" ]]; then
		die "One or more dependencies were built with insufficient use-flags."
	fi
}

src_compile() {
		use dbus || conf_add="${conf_add} no-dbus"
		use portaudio || conf_add="${conf_add} no-portaudio"
		use pulseaudio || conf_add="${conf_add} no-pulseaudio"
		use alsa || conf_add="${conf_add} no-alsa"
		use oss || conf_add="${conf_add} no-oss"
		use texttospeech || conf_add="${conf_add} no-speechd"
	use debug && conf_add="${conf_add} symbols debug"

	qmake "${S}/main.pro" -recursive CONFIG+="${conf_add} release no-server no-bundled-speex" DEFINES+="PLUGIN_PATH=/usr/lib/mumble" \
		|| die "Error while executing qmake."
	emake
}

src_install() {
	newdoc README.Linux README
	dodoc CHANGES

	local dir
	if use debug; then
		dir=debug
	else
		dir=release
	fi

	dobin ${dir}/mumble	|| die "installing failed"

	CONF_LIBDIR="$(get_libdir)/mumble" dolib.so ${dir}/lib*.so* || die "installing libs failed"
	CONF_LIBDIR="$(get_libdir)/mumble" dolib.so ${dir}/plugins/lib*.so* || die "installing libs failed"

	dobin scripts/mumble-overlay || die "installing overlay failed"
	newicon icons/mumble.64x64.png mumble.png || die "installing icon failed"
	make_desktop_entry ${PN} "Mumble" mumble "KDE;Qt;AudioVideo" \
		|| die "installing menu entry failed"

	doman man/mumble-overlay.1
	doman man/mumble.1
	insinto /usr/share/services
	doins scripts/mumble.protocol
}

pkg_postinst() {
	elog
	elog "Visit http://mumble.sourceforge.net/Audio_Tuning for futher configuration"
	elog "type mumble to run the client,"
	elog "type mumble-overlay to start the gaming overlay (after starting mumble)"
}